Modified _ArraySearch()

[GEOSoft]

I have a situation where I need to perform a reverse search on an array but the array can't be modified. So I can't use _ArrayReverse().

I modified SolidSnake's origional to do it. Here it is with the new code commented and a demo. I'm going to submit this for replacement in Array.au3

Edit: It was pointed out that I somehow changed the parameter order and it would have broken existing scripts. This code has now been corrected

expandcollapse popup

$TArray = StringSplit("Array|Color|Date||Dialog|File|Folder|GuiCombo|" & _
"GuiEdit|GuiIPAddress|GuiList|GuiListView|GuiMonthCal|GuiSlider|GuiStatusBar|" & _
"GuiTab|GuiTreeView|IE|Inet|Ini|Language|Math|Memory|Misc|Process", '|')
$aSrch = "GUI"
 $first = _ArraySearch( $TArray, $aSrch, 0, 0, 0,true);; Search forwards
 $last = _ArraySearch( $TArray, $aSrch, 0, 0, 0,true, 1);; Search  backwards
 MsgBox(0,'Test _ArraySearch()', "First = " & $first & @CRLF & "Last = " & $last)

Func _ArraySearch(Const ByRef $avArray, $vFind, $iStart = 0, $iEnd = 0, $iCaseSense = 0, $fPartialSearch = False, $iSearchForward = 0)
;;<<======  Added the [$iSearchForward = 0] parameter and changed $vWhat2Find to the shorter $vFind
    Local $iCurrentPos, $iUBound, $iResult, $iStep = 1, $iBegin, $iStop;; <<===  Added , $iStep = 1, $iBegin, $iStop
    If Not IsArray($avArray) Then
        SetError(1)
        Return -1
    EndIf
    $iUBound = UBound($avArray) - 1
    If $iEnd = 0 Then $iEnd = $iUBound
    If $iStart > $iUBound Then
        SetError(2)
        Return -1
    EndIf
    If $iEnd > $iUBound Then
        SetError(3)
        Return -1
    EndIf
    If $iStart > $iEnd Then
        SetError(4)
        Return -1
    EndIf
    If Not ($iCaseSense = 0 Or $iCaseSense = 1) Then
        SetError(5)
        Return -1
    EndIf
#Region ## <<==========  Start New Code
    If Not ($iSearchForward = 0 Or $iSearchForward = 1) Then
        SetError(7)
        Return -1
    EndIf
    If $iSearchForward = 1 Then
        $iBegin = $iEnd
        $iStop = $iStart
        If $iStop = $iUbound Then $iStop = 0
        $iStep = -1
    Else
    $iBegin = $iStart
    $iStop = $iEnd
    $iStep = 1
    EndIf
#EndRegion;;<<======  End New Code
;For $iCurrentPos = $iStart To $iEnd;;<<======  Changed to the following line
    For $iCurrentPos = $iBegin To $iStop Step $iStep
        Select
            Case $iCaseSense = 0
                If $fPartialSearch = False Then
                    If $avArray[$iCurrentPos] = $vFind Then
                        SetError(0)
                        Return $iCurrentPos
                    EndIf
                Else
                    $iResult = StringInStr($avArray[$iCurrentPos], $vFind, $iCaseSense)
                    If $iResult > 0 Then
                        SetError(0)
                        Return $iCurrentPos
                    EndIf
                EndIf
            Case $iCaseSense = 1
                If $fPartialSearch = False Then
                    If $avArray[$iCurrentPos] == $vFind Then
                        SetError(0)
                        Return $iCurrentPos
                    EndIf
                Else
                    $iResult = StringInStr($avArray[$iCurrentPos], $vFind, $iCaseSense)
                    If $iResult > 0 Then
                        SetError(0)
                        Return $iCurrentPos
                    EndIf
                EndIf
        EndSelect
    Next
    SetError(6)
    Return -1
EndFunc;==>_ArraySearch

Edited August 17, 2007 by GEOSoft

[SmOke_N]

I don't even remember writing that

[GEOSoft]

I don't even remember writing that

That's my mistake. You didn't write it. My appologies to SolidSnake who did write it though.

Note to self. You are about to burn out. ABORT LIFE!!!!