Network, Computer, Software Research

[GreNME]

I do have the code but do to the nature of this program I am not releasing it. Sorry, it only took about day to program.

Why not? No offense, but I was just testing the script to see how it worked, and it hasn't for me in Vista 32-bit. I have GFI's LAN scanner to do the job that this does and more. I was mostly interested in seeing how it was done because I'm curious about learning some AutoIT scripting, not because I need more tools like this.

Like I said, no offense, but I don't see how it's much of an example script if we don't see how you got to where you did. It's not dissimilar from some VB scripts I've seen on Microsoft's Script Center repository, but I think it's cool that you've presented something similar with AutoIT code.

[flip209]

Updated software... See first post for file download....

Edited October 1, 2007 by flip209

[GEOSoft]

Here is where the Good Stuff is.

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall

It shows everything. Hot Fixes. All Details on each Installed Software.

This is right here is good info to know.

This will only work if the Hot Fix is uninstallable. Not all are.

[flip209]

Good point. I will look into it a little more.

[flip209]

LOL ok i found the reg folder that holds that hotfixes, but should I create a separte tab for just hotfixes?

Key is:

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\HotFix

Edited October 1, 2007 by flip209

[GEOSoft]

LOL ok i found the reg folder that holds that hotfixes, but should I create a separte tab for just hotfixes?

Key is:

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\HotFix

I think a separate tab is best.

There are a few methods that can be used to get the list of hot fixes.

• If you have a copy of hotfix.exe on your machine then hotfix.exe /l will get the list
• see the code in my reply to Software Retrieval

Hotfix.exe also can be used for other purposes such as install/uninstall. Here are the switches

/f - Force other programs to quit at shutdown

/l - List installed software updates

/m - Unattended mode

/n - Do not back up files for uninstallation

/q - Quiet mode - no user interaction required

/y - Perform uninstallation (must be used with /m or /q)

/z - Do not restart the computer after the installation

Also see

http://support.microsoft.com/kb/184305/

[flip209]

Added All hotfixes Download EXE on first post...

[flip209]

Add BIOS information... I will post tonight

[flip209]

Just added the bios info

[secman]

I am new to both AUTOIT and this forum. I am very interested in seeing your script but cannot find the file to download on the first post. Can you please let me know where to find the file.

Thanks

[engjcowi]

Hi sorry is this code for viewing? is there a link anywhere?

[flip209]

This is a simple version of the code it will pull installed software, basic system data, and list all current processes:

expandcollapse popup

#Region ;This is the includes and require admin
#include <GUIConstantsEx.au3>
#RequireAdmin
#EndRegion ;This is the includes and require admin

#Region ;Gui Creation and set sate
;Creates Gui
GUICreate("System Information", 550, 550) ; will create a dialog box that when displayed is centered

;creates software button
$btnSoftware = GUICtrlCreateButton("Software", 10, 32, 75, 25)
;creates clear button
$btnSystem = GUICtrlCreateButton("System", 10, 72, 75, 25)
;creates clear button
$btnProcess = GUICtrlCreateButton("Processes", 10, 112, 75, 25)
;creates clear button
$btnClear = GUICtrlCreateButton("Clear", 10, 152, 75, 25)
;creates list
$lstResults = GUICtrlCreateList("", 100, 32, 400, 500)
;creates results label
$lTitle = GUICtrlCreateLabel("Results", 280, 5, 60, 15)
;creates exit button
$btnExit = GUICtrlCreateButton("Exit", 10, 200, 75, 25)


;Shows windows with list and buttons
GUISetState()
#EndRegion ;Gui Creation and set sate
#Region ;While statement waiting for buttons to be pressed

$msg = 0 ; declaring variable for guigetmsg()
While $msg <> $GUI_EVENT_CLOSE ;while loop runs until gui is exited
    $msg = GUIGetMsg() ; variable looking monitors gui for buttons to be pressed

    Select;select for matching $msg to a button variable to run functions
        Case $msg = $btnSoftware ;Triggers when Softare button is pressed
            GUICtrlSetData($lstResults, "");clears listbox
            _InstalledSoftware();runs installed software function
        Case $msg = $btnSystem ;Triggers when system button is pressed
            GUICtrlSetData($lstResults, "");clears listbox
            _SystemInfo();runs system info function
        Case $msg = $btnProcess;triggers when software button is pressed
            GUICtrlSetData($lstResults, "");clears listbox
            _tasks();run task function
        Case $msg = $btnClear;triggers when clear button is pressed
            GUICtrlSetData($lTitle, "Results");sets label to Results
            GUICtrlSetData($lstResults, "");clears listbox
        Case $msg = $btnExit;triggers when exit button is pressed
            Exit;exits program
    EndSelect;ends select statement
WEnd;ends while statement
#EndRegion ;While statement waiting for buttons to be pressed
#Region ; Functions
Func _InstalledSoftware() ;declares the installed software function
    For $i = 1 To 100000 ;Near Endless loop
        ;reads reg edit folder
        $keyfolder = RegEnumKey("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\windows\currentversion\uninstall\", $i)
        ;ends loop if no more folders
        If @error <> 0 Then ExitLoop
        ;Reads software key
        $soft = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\windows\currentversion\uninstall\" & $keyfolder, "DisplayName")
        ;splits strings for comparing
        $Compare = StringSplit($soft, " ")
        ;Compare to check if software key starts with Update
        $cUpdate = $Compare[1]
        ;checks to make sure there are more the two works for Security update compare
        If $Compare[0] > 1 Then $cSecurityUpdate = $Compare[1] & " " & $Compare[2]
        ;Writes display name to list if it exists
        If $soft <> "" And $cUpdate <> "Update" And $cSecurityUpdate <> "Security Update" Then GUICtrlSetData($lstResults, $soft)
    Next ; next for the for loop adds 1 to the count
    ;Change label so you know what results you are looking at
    GUICtrlSetData($lTitle, "Software")
EndFunc   ;==>_InstalledSoftware
Func _SystemInfo() ;declares the system info function
    ;get Physical Memory
    $mem = MemGetStats()
    ;gets processor type
    $Processorname = RegRead("HKLM\Hardware\Description\System\CentralProcessor\0", "ProcessorNameString")
    ;returns os name xp, vista, etc
    GUICtrlSetData($lstResults, "OS: " & @OSVersion)
    ;returns os service pack
    GUICtrlSetData($lstResults, "Service Pack: " & @OSServicePack)
    ;returns computer name
    GUICtrlSetData($lstResults, "Computer Name: " & @ComputerName)
    ;returns domain
    GUICtrlSetData($lstResults, "Domain: " & @LogonDomain)
    ;returns log on server
    GUICtrlSetData($lstResults, "Logon Server: " & @LogonServer)
    ;returns ip address
    GUICtrlSetData($lstResults, "Ip Address: " & @IPAddress1)
    ;returns processor name
    GUICtrlSetData($lstResults, "Processor name: " & $Processorname)
    ;returns physical memory in Megs
    GUICtrlSetData($lstResults, "Physcal memory: " & Round($mem[1] / 1024 / 1024, 1) & " MB")
    ;changes label to system
    GUICtrlSetData($lTitle, "System")
EndFunc   ;==>_SystemInfo
Func _tasks() ;declares the task function
    $list = ProcessList() ;creates and array of processes
    For $i = 1 To $list[0][0] ;for loop the $list[0][0] gives you the number of processes
        GUICtrlSetData($lstResults, $list[$i][0]); adds a the name of each process in listbox
    Next; next statement to match for statment adds 1 to the count
EndFunc   ;==>_tasks
#EndRegion ; Functions

[engjcowi]

Thanks