OShell [Version 1.7] new menu u choose password

Paulie · October 14, 2007

I think you should fix the time so it reads 6:30 PM instead of 18:30

Nahuel · October 14, 2007

Hey Ashley! Check out the changes I made:

#include <GUIConstants.au3>
#include <Misc.au3>
#include <Date.au3>

Opt("RunErrorsFatal",0)

Global $List1, $Close, $Open, $Start, $Form1, $startmenu
Global $DoubleClicked   = False
Global Const $WM_NOTIFY = 0x004E
Global $StartMenuShow=False
Global $DateMenuShow=False

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("OS shell", 633, 430, 193, 115)
$ContMenu=GUICtrlCreateContextMenu()
$Run=GUICtrlCreateMenuItem("Run an application",$ContMenu)
GUICtrlCreateMenuItem("",$ContMenu)
$ChangeColor=GUICtrlCreateMenuItem("Change Background Color",$ContMenu)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetBkColor(0x808080)
$Start = GUICtrlCreateButton("Start", 3, 409, 75, 17, 0)
$Open = GUICtrlCreateButton("Open", 3, 409, 75, 17, 0)
GUICtrlSetState(-1, $GUI_HIDE)
$startmenu = GUICtrlCreateListView("Applications ", 8, 305, 85, 97,$LVS_NOSORTHEADER)
GUICtrlSetState(-1, $GUI_HIDE)
GUICtrlCreateListViewItem("Paint",$startmenu )
GUICtrlSetImage (-1, "shell32.dll",-35)
GUICtrlCreateListViewItem("Notepad",$startmenu )
GUICtrlSetImage (-1, "shell32.dll",-71)
$date = GUICtrlCreateMonthCal("2007/10/14", 432, 246, 191, 161)
GUICtrlSetState(-1, $GUI_HIDE)
$Time = GUICtrlCreateButton(_NowTime(), 544, 409, 75, 17, 0)
$Paint = GUICtrlCreateButton("Paint", 8, 8, 59, 49,BitOR($BS_PUSHBOX,$BS_FLAT,$BS_ICON))
GUICtrlSetImage (-1, "shell32.dll",-35)
$Notepad = GUICtrlCreateButton("Notepad", 8, 80, 59, 49, BitOR($BS_PUSHBOX,$BS_FLAT,$BS_ICON))
GUICtrlSetImage (-1, "shell32.dll",-71)
GUISetState()
#EndRegion ### END Koda GUI section ###

AdlibEnable("refresh_time",1000)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Start
            Startmenu()
        Case $Time
            If not $DateMenuShow Then
                GUICtrlSetState($date, $GUI_SHOW)
                $DateMenuShow=True
            Else
                GUICtrlSetState($date, $GUI_HIDE)
                $DateMenuShow=False
            EndIf
        Case $Paint
            GUICtrlDelete($Paint)
            $Paint = GUICtrlCreateButton("Paint", 8, 8, 59, 49,BitOR($BS_PUSHBOX,$BS_FLAT,$BS_ICON))
            GUICtrlSetImage (-1, "shell32.dll",-35)
            Run("MSpaint")
        Case $Notepad
            GUICtrlDelete($Notepad)
            $Notepad = GUICtrlCreateButton("Notepad", 8, 64, 59, 49, BitOR($BS_PUSHBOX,$BS_FLAT,$BS_ICON))
            GUICtrlSetImage (-1, "shell32.dll",-71)
            Run("notepad")
        Case $Run
            _Run()
        Case $ChangeColor
            _ChangeColor()
        EndSwitch
    If $DoubleClicked Then
        DoubleClickFunc()
        $DoubleClicked = False
    EndIf
WEnd
Func Startmenu()
    If not $StartMenuShow Then
        GUICtrlSetState($Startmenu, $GUI_SHOW)
        $StartMenuShow=True
    Else
        GUICtrlSetState($Startmenu, $GUI_HIDE)
        $StartMenuShow=False
    EndIf

EndFunc

Func refresh_time()
    GUICtrlSetData($Time,_NowTime())
EndFunc

Func WM_NOTIFY($hWnd, $MsgID, $wParam, $lParam)
    Local $tagNMHDR, $event, $hwndFrom, $code
    $tagNMHDR = DllStructCreate("int;int;int", $lParam)
    If @error Then Return 0
    $code = DllStructGetData($tagNMHDR, 3)
    If $wParam = $startmenu And $code = -3 Then $DoubleClicked = True
    Return $GUI_RUNDEFMSG
EndFunc

Func DoubleClickFunc()
   $App=GUICtrlRead(GUICtrlRead($Startmenu))
   Switch $App
       Case "Notepad"
           Run("notepad")
       Case "Paint"
            Run("mspaint")
    EndSwitch
EndFunc

Func _Run()
    GUISetState(@SW_DISABLE,$Form1)
    $RunCHild=GUICreate("Run", 291, 120, 226, 156, BitOR($WS_SYSMENU,$WS_CAPTION,$WS_POPUP,$WS_POPUPWINDOW,$WS_BORDER,$WS_CLIPSIBLINGS),-1,$Form1)
    GUICtrlCreateLabel("Type the name of the application you wish to execute", 8, 16, 276, 17)
    $Path = GUICtrlCreateInput("", 8, 40, 273, 21)
    $RunButton = GUICtrlCreateButton("&Run", 8, 80, 73, 25, $BS_DEFPUSHBUTTON)
    $CancelButton= GUICtrlCreateButton("&Cancel", 104, 80, 75, 25, 0)
    $Browse = GUICtrlCreateButton("&Browse", 200, 80, 75, 25, 0)
    GUISetState()
    While 1
        $CMsg=GUIGetMsg()
        Select 
        Case $CMsg=$GUI_EVENT_CLOSE OR $CMsg=$CancelButton
            GUISetState(@SW_ENABLE,$Form1)
            GUIDelete($RunChild)
            ExitLoop
        Case $CMsg=$RunButton
            Run(GUICtrlRead($Path))
            If @error Then
                MsgBox(4112,"Error","Unable to execute external program")
            Else
                GUISetState(@SW_ENABLE,$Form1)
                GUIDelete($RunChild)
                ExitLoop
            EndIf
        Case $CMsg=$Browse
            $PathOfFile=FileOpenDialog("Run Application",@Programfilesdir,"Programs (*.exe)", 1 )
            If not @error Then
                GUICtrlSetData($Path,$PathofFile)
            EndIf
        EndSelect
    WEnd
EndFunc


Func _ChangeColor()
    $bkColor=_ChooseColor(2)
    If not @error Then
        GUISetBkColor($bkColor)
    EndIf
EndFunc

*Removed X buttons

*Changed time format in time button

*Added context menu

*Run application

*Change background color

Edited October 14, 2007 by Nahuel

JustinReno · October 14, 2007

It looks good!

Dhilip89 · October 15, 2007

It look nice.

Some suggestion:

1.Make it full screen.

2.Able to set wallpaper.

3.Right click menu.

ashley · October 15, 2007

thanks for the feedback everybody.

Nahuel thanks for the script i will check that l8er im at school ATM and they dont have autoit.(even tho the admin makes programs with it ,that teachers use(i recognise the icon))

alien13 · October 15, 2007

This is cool. I don't really have any suggestions apart from having it save the background color like so -(attached script)-. Good work!

alein13

ShellOS.au3

ashley · October 15, 2007

UPDATED check first post, FULL SCREEN NOT INCLUDED

Edited October 15, 2007 by ashley

ashley · October 15, 2007

what do you all think of the new updates?

Can anybody see a way to fix the bugs?(I cant)

Edited October 15, 2007 by ashley

Monamo · October 15, 2007

Very nifty. One item of note - in the line:

$date = GUICtrlCreateMonthCal("2007/10/14", 432, 246, 191, 161)

... be sure to clear the default date value in the quotes before compiling so 14 OCT isn't selected by default (today's date was correctly defined, but the 14th had a red "selection" border).

ashley · October 15, 2007

Monamo said:
Very nifty. One item of note - in the line:
$date = GUICtrlCreateMonthCal("2007/10/14", 432, 246, 191, 161)
... be sure to clear the default date value in the quotes before compiling so 14 OCT isn't selected by default (today's date was correctly defined, but the 14th had a red "selection" border).

tyvm FOR THE FEEDBACK, ANY IDEAS ON HOW TO FIX THE OTHER BUGS.

ashley · October 15, 2007

FIXED the bug with date

Edited October 15, 2007 by ashley

jvanegmond · October 15, 2007

You might be able to transform this into some sort of hacking game or so..

health · October 15, 2007

this is a little script to demonstrate the full screen function. the code is quiet dirty but you make it.

CODE

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****

#AutoIt3Wrapper_icon=Icon.ico

#AutoIt3Wrapper_Res_Comment=Viel Spaß

#AutoIt3Wrapper_Res_Description=Blitzer

#AutoIt3Wrapper_Res_Fileversion=1.0.0.1

#AutoIt3Wrapper_Res_LegalCopyright=Paul

#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <GuiConstants.au3>

#region Global Variables and Constants

Global Const $WM_NCPAINT = 133 ; Message Rahmen neu zeichnen

Global Const $GWL_STYLE = -16 ; Windowstyle mit GetWindowLong/SetWindowLong abfragen/setzen

Global Const $GWL_EXSTYLE = -20 ; erweiterter Windowstyle mit GetWindowLong/SetWindowLong abfragen/setzen

#endregion

$Wait = 60

HotKeySet("{ESC}", "Ende")

$GUI = GUICreate("Techno")

_SetWinStyle($GUI)

GUISetCursor(16) ; maus verstecken

WinSetOnTop($GUI, "", 1)

GUISetState()

GUISetState(@SW_MAXIMIZE)

While 1

Sleep($Wait)

GUISetBkColor(0x000000, $GUI)

Sleep($Wait)

GUISetBkColor(0xFFFFFF, $GUI)

WEnd

Func Ende()

Exit

EndFunc

;===============================================================================

Func _SetWinStyle($StyleHandle)

$wh = WinGetHandle($StyleHandle)

$WinStyle = _WinGetStyle($wh)

; _WinSetStyle($wh, "", BitAND($WinStyle[0], BitNOT($WS_OVERLAPPEDWINDOW)))

_WinSetStyle($wh, "", BitAND($WinStyle[0], BitNOT($WS_OVERLAPPEDWINDOW), BitNOT($WS_EX_TOOLWINDOW) ) )

;;;;;;

dllCall("user32.dll", "long", "ShowWindow", "hwnd", $wh, "long", 0)

dllCall("user32.dll", "long", "SetWindowLong", "hwnd", $wh, "int", -20, "long", 0x80)

dllCall("user32.dll", "long", "ShowWindow", "hwnd", $wh, "long", 5)

EndFunc

;===============================================================================

;

; Description: Gibt die Fensterstile zurück

; Parameter(s): $WinTitle = Handle oder Titel des Fensters, das gelesen werden soll

; (optional) $WinText = Text des Fensters, das gelesen werden soll

; Requirement(s): keine

; Return Value(s): bei Erfolg: Array{0] = Fensterstil

; Array[1] = erweiterter Fensterstil

; bei Fehler: Leerstring und @error = 1

; Author(s): bernd670

;

;===============================================================================

Func _WinGetStyle($WinTitle, $WinText = "")

Local $RetValue[2], $Temp, $h_window

$h_window = $WinTitle

If Not IsHWnd($h_window) Then

$h_window = WinGetHandle($WinTitle, $WinText)

If @error Then

SetError(1)

Return ""

EndIf

; read Windowstyle

$Temp = DllCall("user32.dll", "long", "GetWindowLong", "hwnd", $h_window, "long", $GWL_STYLE)

If @error Then

SetError(1)

Return ""

EndIf

$RetValue[0] = $Temp[0]

; read extended Windowstyle

$Temp = DllCall("user32.dll", "long", "GetWindowLong", "hwnd", $h_window, "long", $GWL_EXSTYLE)

If @error Then

SetError(1)

Return ""

EndIf

$RetValue[1] = $Temp[0]

SetError(0)

Return $RetValue

EndFunc

;===============================================================================

;

; Description: setzt die Fensterstile

; Parameter(s): $WinTitle = Handle oder Titel des Fensters, das gelesen werden soll

; (optional) $WinText = Text des Fensters, das gelesen werden soll

; (optional) $Style = Fensterstil (Standard = $WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU)

; (optional) $ExStyle = erweiterter Fensterstil (Standard = $WS_EX_APPWINDOW ,$WS_EX_WINDOWEDGE)

; Requirement(s): keine

; Return Value(s): bei Erfolg: 1

; bei Fehler: 0 und @error = 1

; Author(s): bernd670

;

;===============================================================================

Func _WinSetStyle ($WinTitle, $WinText = "", $Style = -1, $ExStyle = -1)

Local $h_window

$h_window = $WinTitle

If Not IsHWnd($h_window) Then

$h_window = WinGetHandle($WinTitle, $WinText)

If @error Then

SetError(1)

Return 0

EndIf

; write Windowstyle

If $Style = -1 Then $Style = BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU)

DllCall("user32.dll", "long", "SetWindowLong", "hwnd", $h_window, "long", $GWL_STYLE, "long", $Style)

If @error Then

SetError(1)

Return 0

EndIf

; write extended Windowstyle

If $ExStyle = -1 Then $ExStyle = BitOR($WS_EX_APPWINDOW ,$WS_EX_WINDOWEDGE)

DllCall("user32.dll", "long", "SetWindowLong", "hwnd", $h_window, "long", $GWL_EXSTYLE, "long", $ExStyle)

If @error Then

SetError(1)

Return 0

EndIf

DllCall("user32.dll", "int", "SendMessage", "hwnd", $h_window, "int", $WM_NCPAINT, "int", 1, "int", 0)

SetError(0)

Return 1

EndFunc

suggestion:

make GUICtrlSetCursor(0) for buttons and any else

Edited October 15, 2007 by health

ashley · October 15, 2007

UPDATED take a look

ashley · October 15, 2007

EXE Released

ashley · October 15, 2007

Please vote in my poll!!!

BE honest!!!!

ashley · October 15, 2007

Dhilip89 said:
It look nice.
Some suggestion:
1.Make it full screen.
2.Able to set wallpaper.
3.Right click menu.

1) DONE

2) I Dont know how

3) DONE

ashley · October 15, 2007

well what do ya all think???

Good/Bad

Surgestions?

Bug fixes?

New functions?

Looks?

ANYTHING?

Jos · October 15, 2007

What about cooling down a bit and stop spamming your own thread for a day ?

Edited October 15, 2007 by Jos

Nahuel · October 15, 2007

That looks very good Ashley! You could take a look at _ControlHover.au3 to hide the Start menu when the mouse is not over it. And maybe add more apps, would be nice to something made by you.

Btw, what's that poll for? Looks like you are in a competition or something...

Sign In

OShell [Version 1.7] new menu u choose password

Recommended Posts

Paulie

Top Posters In This Topic

Top Posters In This Topic

Nahuel

JustinReno

Dhilip89

ashley

alien13

ashley

ashley

Monamo

ashley

ashley

jvanegmond

health

ashley

ashley

ashley

ashley

ashley

Jos

Nahuel

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta

OShell [Version 1.7] *new menu* *u choose password*

Recommended Posts

Top Posters In This Topic

Top Posters In This Topic

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

OShell [Version 1.7] new menu u choose password