_IECreate("about:blank",0,0,1,-1) IE window hidden

[tradertt]

Hi guys,

I have a script that auto enters some data into a web form database. I wish to hide it which is why I used _IECREATE with the option 0 for hidden window.

However, sometimes, in order to check the progress, I would like to show the hidden window when I activate some keypresses

Is there a easy way to do it?

[Thatsgreat2345]

#include <IE.au3>
$oIE = _IECreate('',0,0)
$oHandle = _IEPropertyGet($oIE,'hwnd')
Sleep(3000)
WinSetState($oHandle,'',@SW_SHOW)
Sleep(3000)
WinSetState($oHandle,'',@SW_HIDE)

EDIT: Read your post wrong xD

Edited February 6, 2008 by Thatsgreat2345

[DaleHohm]

tgreat's method will work, another is using _IEAction($oIE, "visible") and _IEAction($oIE, "invisible") in conjunction with HotKeySet

Dale

[tradertt]

#RequireAdmin
#include<IE.au3>
#include<File.au3>
#include<GUIConstants.au3>
#include<Array.au3>

HotKeySet("+!h", "hidewindow") ;Shift-Alt-h
HotKeySet("+!s", "showwindow") ;Shift-Alt-s

_FileReadToArray($LinkSource,$Links)
_IELoadWaitTimeout($Timeout)
_IEErrorHandlerRegister()
$oIE=_IECreate("about:blank",0,$IEStatus,1,-1)
For $o=0 to $Repeat
    For $i=0 to $Amount     
        MAIN BODY OF CODE
Next

Func hidewindow()
    _IEAction($oIE, "visible")
EndFunc

Func showwindow()
    _IEAction($oIE, "invisible")
EndFunc

I am sorry did I do something wrong for Hotkey set.

Tried it but it does not seem to hide the window when I pressed Shift Alt h and show it when I pressed Shift Alt s

[tradertt]

Can anyone help me on how do I use hotkeys, tried following the help file but it did not seem to work. NOthing happens when I pressed the hotkey set

[Valuater]

Just for the window ( not your code )

maybe...

expandcollapse popup

#RequireAdmin
#include<IE.au3>
#include<File.au3>
#include<GUIConstants.au3>
#include<Array.au3>

HotKeySet("{F8}", "hidewindow")
HotKeySet("{F9}", "showwindow")
HotKeySet("{ESC}", "_Exit")

;_FileReadToArray($LinkSource,$Links)
;_IELoadWaitTimeout($Timeout)
_IEErrorHandlerRegister()
$oIE = _IECreate("about:blank");,0,$IEStatus,1,-1)
$oHandle = _IEPropertyGet($oIE, 'hwnd')

;'For $o=0 to $Repeat
;   For $i=0 to $Amount
;       MAIN BODY OF CODE
;Next

While WinExists($oHandle)
    Sleep(20)
WEnd


Func hidewindow()
    _IEAction($oIE, "invisible")
EndFunc   ;==>hidewindow

Func showwindow()
    _IEAction($oIE, "visible")
EndFunc   ;==>showwindow

Func _Exit()
    $oIE = ""
    Exit
EndFunc   ;==>_Exit

$oIE = ""
Exit

8)

[tradertt]

Hi

Thank you. It works

[Thatsgreat2345]

I recommend using my method as occasionally use some IE COM functions cause the script to crash so I try to use some Win* functions just because they are safer.