Why not names it random please help screenshot name random 001 002 003

[Best4FREE]

#include <Misc.au3>

#include <ScreenCapture.au3>

HotKeySet("{ESC}", "Terminate")

HotKeySet ("{F1}","Screencaputure" )

Func Terminate()

Exit 0

EndFunc

Func Screencaputure()

Local $number = 1

Local $capture = _ScreenCapture_Capture("", 240, 355, 429, 406, False)

Local $save = _ScreenCapture_SaveImage(@scriptDir & "\Screenshots\Screenshot " & $number & ".bmp", $capture)

$number = $number + 1

EndFunc

while 1

sleep (1000)

WEnd

why it overwrite the old screenshot i wanna that it name screenshot like 001 002 003

[BigDod]

#include <Misc.au3>

#include <ScreenCapture.au3>

HotKeySet("{ESC}", "Terminate")

HotKeySet ("{F1}","Screencaputure" )

Func Terminate()

Exit 0

EndFunc

Func Screencaputure()

Local $number = 1

Local $capture = _ScreenCapture_Capture("", 240, 355, 429, 406, False)

Local $save = _ScreenCapture_SaveImage(@scriptDir & "\Screenshots\Screenshot " & $number & ".bmp", $capture)

$number = $number + 1

EndFunc

while 1

sleep (1000)

WEnd

why it overwrite the old screenshot i wanna that it name screenshot like 001 002 003

You are setting $number back to 1 at the start of your function.

[Jos]

What do you think this line does ?

Local $number = 1

You need to make it a Global variable to be able to add 1 to it each time... something like:

#include <Misc.au3>
#include <ScreenCapture.au3>
Global $number = 1
HotKeySet("{ESC}", "Terminate")
HotKeySet("{F1}", "Screencaputure")
While 1
    Sleep(1000)
WEnd
;
Func Terminate()
    Exit 0
EndFunc ;==>Terminate
;
Func Screencaputure()
    Local $capture = _ScreenCapture_Capture("", 240, 355, 429, 406, False)
    Local $save = _ScreenCapture_SaveImage(@ScriptDir & "\Screenshots\Screenshot " & $number & ".bmp", $capture)
    $number = $number + 1
EndFunc ;==>Screencaputure

Edited March 26, 2008 by Jos

[Best4FREE]

WOrking ?

[Jos]

WOrking ?

No, my work is done for the day ... its evening here.

..but if you mean: Is the script worling then I tell you I don't know... just wanted to show you where to define the variable , thats all.

You are supposed to do the rest of the work yourself.

Jos

Edited March 26, 2008 by Jos

[GEOSoft]

something else that hasn't been mentioned yet. If you want 001, 002, 003 etc the you also have to add some code to pad $number with leading 0s.

If StringLen($number) < 3 Then
   Do
      $number = "0" & $number
   Until StringLen($number) = 3
EndIf

Edited March 26, 2008 by GEOSoft

[Jos]

I know you are going to curse me for this but this is what I normally use:

StringRight("000"& $number,3)

[everseeker]

I know you are going to curse me for this but this is what I normally use:

StringRight("000"& $number,3)

I like that..... Going to file that nugget away!!!!!

[weaponx]

For $X = 0 to 100
    ConsoleWrite(StringFormat("%03i", $X) & @CRLF);000, 001, 002....100
Next

[GEOSoft]

I know you are going to curse me for this but this is what I normally use:

StringRight("000"& $number,3)

I won't curse you for posting that. I'll just grumble about it for a couple of hour. That's really nice, efficient code. Mine looks like it's actually doing something.

Edit: Besides I thing you gave an incomplete statement.

$number = StringRight("000" & $number, 3)
 ;;name the file in here and then
$number +=1

Edited March 26, 2008 by GEOSoft

[Jos]

Edit: Besides I thing you gave an incomplete statement.

$number = StringRight("000" & $number, 3)
;;name the file in here and then
$number +=1

Nah..

I would:

Local $save = _ScreenCapture_SaveImage(@ScriptDir & "\Screenshots\Screenshot " & StringRight("000" & $number, 3) & ".bmp", $capture)
    $number +=1

[GEOSoft]

Nah..

I would:

Local $save = _ScreenCapture_SaveImage(@ScriptDir & "\Screenshots\Screenshot " & StringRight("000" & $number, 3) & ".bmp", $capture)
    $number +=1

OK Ninja coder, you made your point and I lose again.