FileSaveDialog - append?

[gcue]

theres an option in FileSaveDialog for prompting for replacement.

would it be possible at all to include an option for appending?

text file appending for instance.

[Monamo]

theres an option in FileSaveDialog for prompting for replacement.

would it be possible at all to include an option for appending?

text file appending for instance.

Here's an example (basically, using FileOpen(in append mode) instead of FileSave, then FileWriteLine for the new data):

expandcollapse popup

#include <GUIConstants.au3>
AutoItSetOption("GUIOnEventMode", 1)

$GUITitle = "Append to file example"
$GUIWidth = 400
$GUIHeight = 300

$GUI = GUICreate($GUITitle, $GUIWidth, $GUIHeight, (@DesktopWidth - $GUIWidth) / 2, (@DesktopHeight - $GUIHeight) / 2)
$editBody = GUICtrlCreateEdit("", 10, 10, $GUIWidth - 20, $GUIHeight - 40)
$buttonAppend = GUICtrlCreateButton("Append to existing file...", 10, $GUIHeight - 20, $GUIWidth - 20, 20, $BS_FLAT)

GUISetState()

#Region Events list
GUISetOnEvent($GUI_EVENT_CLOSE, "_ExitIt")
GUICtrlSetOnEvent($buttonAppend, "_AppendData")
#EndRegion Events list

While 1
    Sleep(10)
WEnd

Func _AppendData()
    $sFile = ""
    If GUICtrlRead($editBody) <> "" Then
        $sFile = FileOpenDialog("Select destination file...", @ScriptDir, "Text files (*.txt)", 8)
        If Not @error Then
            $hFile = FileOpen($sFile, 1)
            FileWriteLine($hFile, GUICtrlRead($editBody))

            If @error Then
                MsgBox(48, "Error", "Error appending data to target file.")
            EndIf
            
            FileClose($hFile)
        EndIf
    EndIf
EndFunc

Func _ExitIt()
    Exit
EndFunc