Using variables with objects

[JonnyThunder]

Hello,

Im using various WMI queries to extract information on a PC. I'd have a bit of code like this...

$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_BaseBoard", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
If IsObj($colItems) then
    Dim $data_motherboard[5]
    For $objItem In $colItems
        $data_motherboard[0] = $objItem.Manufacturer
        $data_motherboard[1] = $objItem.Model
        $data_motherboard[2] = $objItem.Product
        $data_motherboard[3] = $objItem.SerialNumber
        $data_motherboard[4] = $objItem.Version
    Next
Else
    $data_motherboard = False
Endif

Is there any way to use a variable in place of the object properties? So instead of....

$objitem.Manufacturer

I'm after something like...

$objitem.$mypropertyname

I've tried it as above, but it doesn't work. Is there any way of doing this?

Thanks,

JT

[PsaltyDS]

Good coffee this morning:

#include <Array.au3>
$sProperty = "Manufacturer"
$objWMIService = ObjGet("WINMGMTS:\\.\ROOT\CIMV2")
$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_BaseBoard", "WQL")
Dim $data_motherboard[5]
If IsObj($colItems) then
    For $objItem In $colItems
        $sData = Eval("objItem." & $sProperty)
        $data_motherboard[0] = $objItem.Manufacturer
       ; $data_motherboard[0] = $objItem.Manufacturer
        $data_motherboard[1] = $objItem.Model
        $data_motherboard[2] = $objItem.Product
        $data_motherboard[3] = $objItem.SerialNumber
        $data_motherboard[4] = $objItem.Version
    Next
Else
    $data_motherboard[0] = False
Endif

_ArrayDisplay($data_motherboard, "$data_motherboard")

[JonnyThunder]

This script does work, but not sure what you mean by it!

It's still pulling information from those properties without variables.

Edited June 30, 2008 by JonnyThunder

[PsaltyDS]

This script does work, but not sure what you mean by it!

It's still pulling information from those properties without variables.

My mistake, posted the wrong version. I was trying various things with Eval(), Execute(), etc. Here is the one that worked and should have been posted to begin with:

#include <Array.au3>
$sProperty = "Manufacturer"
$objWMIService = ObjGet("WINMGMTS:\\.\ROOT\CIMV2")
$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_BaseBoard", "WQL")
Dim $data_motherboard[5]
If IsObj($colItems) then
    For $objItem In $colItems
        $sData = Execute("$objItem." & $sProperty)
        $data_motherboard[0] = $sData
       ; $data_motherboard[0] = $objItem.Manufacturer
        $data_motherboard[1] = $objItem.Model
        $data_motherboard[2] = $objItem.Product
        $data_motherboard[3] = $objItem.SerialNumber
        $data_motherboard[4] = $objItem.Version
    Next
Else
    $data_motherboard[0] = False
Endif

_ArrayDisplay($data_motherboard, "$data_motherboard")

[JonnyThunder]

Ahh, thats brilliant. i actually went down the same way of thinking and tried eval, but not execute.

Thanks for your post PsaltyDS. Mucho appreciate-o.

/nicotine required.