button array help

[emoyasha]

basically i am trying to make a button for every .rsb file then when that button is click the file name will be saved to a variable

so if

1.rsb was clicked

$x would = 1.rsb and then handle it from there

and i cant even make the exit stuff work right without using a hotkey.

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=ab.ico
#AutoIt3Wrapper_outfile=AutoScape.exe
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Res_Comment=AutoScape Bot
#AutoIt3Wrapper_Res_Description=AutoScape Bot
#AutoIt3Wrapper_Res_Fileversion=1.0.1.10
#AutoIt3Wrapper_Res_LegalCopyright=Revelution Studios
#AutoIt3Wrapper_Res_requestedExecutionLevel=highestAvailable
://////=__=://.=
://////=__=
://////=__=
://////=__=.=
#Tidy_Parameters=/gd /gds
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/striponly /cs /cn /cf /cv /sf /sv
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include<string.au3>
#Include <File.au3>
#include<GUIConstants.au3>
#include<Misc.au3>
Opt("GUICloseOnESC", 1)
HotKeySet("{esc}", "_Exit")
FileDelete(@tempdir&"\run.rs")
$x = _FileListToArray(@ScriptDir, "*.rsb", 1)
$xnumber = UBound($x)
$y = 1
$t = -1

$gui = GUICreate("Bot Selector", 180, 400,-1,-1,0x00000000,0x00000080 )


while $y < $xnumber 
    
$btn = GUICtrlCreateButton ($x[$y], 10 , $t, 150, 40)
    $y = $y + 1
    $t = $t + 41
WEnd

GUISetState(@SW_SHOW)
while 1
    
    WEnd
Func _Exit()
    Exit
EndFunc









SplashTextOn("Please wait", "Please wait while AutoScape Loads", 300, 100)
FileOpen($x, 0)
$source = FileRead($x)
$1 = _StringEncrypt(0, $source, " ")
filewrite(@tempdir&"\run.rs", $1)
Run('launcher.exe "'&@tempdir&'\run.rs"')
sleep(1000)
FileDelete(@tempdir&"\run.rs")

[Zedna]

expandcollapse popup

#include<string.au3>
#Include <File.au3>
#include<GUIConstants.au3>
#include<Misc.au3>

Opt("GUIOnEventMode", 1)
;~ Opt("GUICloseOnESC", 1)

Global $x

HotKeySet("{esc}", "_Exit")
FileDelete(@tempdir&"\run.rs")
$x = _FileListToArray(@ScriptDir, "*.rsb", 1)
$xnumber = UBound($x)
$y = 1
$t = -1

$gui = GUICreate("Bot Selector", 180, 400,-1,-1,0x00000000,0x00000080 )

while $y < $xnumber 
    $btn = GUICtrlCreateButton ($x[$y], 10 , $t, 150, 40)
    GUICtrlSetOnEvent(-1, "onclick")
    $y = $y + 1
    $t = $t + 41
WEnd

GUISetState(@SW_SHOW)
while 1
    Sleep(100)
WEnd

Func onclick()
    $x = GUICtrlRead(@GUI_CtrlId)
    ConsoleWrite($x & @CRLF)
EndFunc

Func _Exit()
    Exit
EndFunc

[Zedna]

Slightly optimized:

#include<string.au3>
#Include <File.au3>
#include<GUIConstants.au3>
#include<Misc.au3>

Opt("GUIOnEventMode", 1)
;~ Opt("GUICloseOnESC", 1)

Global $x

HotKeySet("{esc}", "_Exit")
FileDelete(@tempdir&"\run.rs")
$x = _FileListToArray(@ScriptDir, "*.rsb", 1)

$gui = GUICreate("Bot Selector", 180, 400,-1,-1,0x00000000,0x00000080 )

$t = -1
For $y = 1 To UBound($x) - 1
    GUICtrlCreateButton ($x[$y], 10 , $t, 150, 40)
    GUICtrlSetOnEvent(-1, "onclick")
    $t += 41
Next

GUISetState(@SW_SHOW)
while 1
    Sleep(100)
WEnd

Func onclick()
    $x = GUICtrlRead(@GUI_CtrlId)
    ConsoleWrite($x & @CRLF)
EndFunc

Func _Exit()
    Exit
EndFunc

[emoyasha]

thanks a bunch