Help with run command.

[Glyph]

Run(@ComSpec & ' /c ' & "tracert "&$dahip, '', @SW_show)

fixed!

Edited August 12, 2008 by BackStabbed

[PsaltyDS]

Run("cmd.exe /k tracert "&$dahip)

fixed!

It's good that you figured out how to leave the "DOS Box" open so you could read the results. If you would like to access the results programmatically, then you would either redirect the results to a file:

$sTRText = "C:\Temp\TraceRoute.txt"
Run("cmd.exe /c tracert " & $dahip & " > " & $sTRText)

...or capture the output with $STDOUT_CHILD and StdOutRead():

#include <Constants.au3>
#include <Array.au3>

Global $dahip = "127.0.0.1", $sOutput = ""

Global $iPID = Run(@ComSpec & " /c tracert " & $dahip, @TempDir, @SW_MINIMIZE, $STDOUT_CHILD)

While 1
    $sOutput &= StdoutRead($iPID)
    If @error Then ExitLoop
WEnd

; Remove blank lines
$avOutput = StringSplit($sOutput, @CRLF)
For $n = $avOutput[0] To 1 Step -1
    If StringStripWS($avOutput[$n], 8) = "" Then _ArrayDelete($avOutput, $n)
Next
$sOutput = _ArrayToString($avOutput, @CRLF, 1)

; Display result
MsgBox(64, "TraceRt", $sOutput)

P.S. This shows a more efficient way to remove blank lines:

#include <Constants.au3>

Global $dahip = "127.0.0.1", $sOutput = ""

Global $iPID = Run(@ComSpec & " /c tracert " & $dahip, @TempDir, @SW_MINIMIZE, $STDOUT_CHILD)

While 1
    $sOutput &= StdoutRead($iPID)
    If @error Then ExitLoop
WEnd

; Remove blank lines
$sOutput = StringRegExpReplace($sOutput, "\s{2,}", @CRLF)

; Display result
MsgBox(64, "TraceRt", $sOutput)

Edit: Changed "/k" back to "/c" in my examples.

Edited August 12, 2008 by PsaltyDS

[Glyph]

Wow, I like this much better!

I can make my own UI for this instead of a seperate cmd box!

greatly appreciated, thanks!

Edited August 12, 2008 by BackStabbed