need more input help for gui

[nonplayablecharacter]

i've been trying to get a msg box to pop up when the input box for a gui is clicked i've spent about the past half hour trying to do it...can someone give me some guidance i've been trying to do it with GUICtrlGetState but no success...basically i want the input to act like a button that will deactivate if its not $GUI_FOCUS

CODE

#include <GUIConstants.au3>

GUICreate("GUI",320,120)

GUICtrlCreateInput ( "", 10, 5, 300, 20)

GUISetState ()

While 1

$msg = GUIGetMsg()

Switch $msg

Case $GUI_EVENT_CLOSE

Exit

EndSwitch

Wend

Edited August 19, 2008 by nonplayablecharacter

[PsaltyDS]

i've been trying to get a msg box to pop up when the input box for a gui is clicked i've spent about the past half hour trying to do it...can someone give me some guidance i've been trying to do it with GUICtrlGetState but no success...basically i want the input to act like a button that will deactivate if its not $GUI_FOCUS

#include <GUIConstants.au3>

GUICreate("GUI",320,120)
GUICtrlCreateInput ( "", 10, 5, 300, 20)

GUISetState () 

While 1
$msg = GUIGetMsg()
Switch $msg
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
Wend

I don't see an event for clicking on an input control, but there is one if you hit enter and there are any changes to the input. Demo used GuiOnEventMode:

expandcollapse popup

#include <GuiConstants.au3>

Opt("GuiOnEventMode", 1)

Global $hGUI = GUICreate("Test", 500, 300)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Quit")
GUICtrlCreateLabel("Type something and hit enter:", 10, 10, 480, 20)
Global $ctrlInput = GUICtrlCreateInput("", 10, 40, 480, 20)
GUICtrlSetOnEvent(-1, "_InputBox")
GUICtrlCreateButton("Enable", 100, 250, 100, 30)
GUICtrlSetOnEvent(-1, "_ButtonHit")
GUICtrlCreateButton("Disable", 300, 250, 100, 30)
GUICtrlSetOnEvent(-1, "_ButtonHit")

GUISetState()

While 1
    Sleep(20)
WEnd

Func _Quit()
    Exit
EndFunc

Func _InputBox()
    ConsoleWrite("Text = " & ControlGetText(@GUI_WinHandle, "", @GUI_CtrlHandle) & @LF)
EndFunc

Func _ButtonHit()
    Switch ControlGetText(@GUI_WinHandle, "", @GUI_CtrlHandle)
        Case "Enable"
            ControlEnable(@GUI_WinHandle, "", $ctrlInput)
            ControlFocus(@GUI_WinHandle, "", $ctrlInput)
        Case "Disable"
            ControlDisable(@GUI_WinHandle, "", $ctrlInput)
    EndSwitch
EndFunc

[nonplayablecharacter]

I don't see an event for clicking on an input control

yea thats my problem...is there way to make an invisible button that i can put on top of an input? (Sorry but the code you posted is not much help) or anyone else can answer that question

Edited August 20, 2008 by nonplayablecharacter

[PsaltyDS]

yea thats my problem...is there way to make an invisible button that i can put on top of an input? (Sorry but the code you posted is not much help) or anyone else can answer that question

The problem is, input controls use mouse clicks internally (i.e. to change cursor position) so they don't pass the message to the GUI. Consider this version of the demo:

expandcollapse popup

#include <GuiConstants.au3>

Global Const $WM_LBUTTONDOWN = 0x0201 

Opt("GuiOnEventMode", 1)

Global $hGUI = GUICreate("Test", 500, 300)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Quit")
GUICtrlCreateLabel("Type something and hit enter:", 10, 10, 480, 20)
Global $ctrlInput = GUICtrlCreateInput("", 10, 40, 480, 20)
GUICtrlSetOnEvent(-1, "_InputBox")
GUICtrlCreateButton("Enable", 100, 250, 100, 30)
GUICtrlSetOnEvent(-1, "_ButtonHit")
GUICtrlCreateButton("Disable", 300, 250, 100, 30)
GUICtrlSetOnEvent(-1, "_ButtonHit")

GUIRegisterMsg($WM_LBUTTONDOWN, "_Mouse_L_Button")

GUISetState()

While 1
    Sleep(20)
WEnd

Func _Quit()
    Exit
EndFunc

Func _InputBox()
    ConsoleWrite("Text = " & ControlGetText(@GUI_WinHandle, "", @GUI_CtrlHandle) & @LF)
EndFunc

Func _ButtonHit()
    Switch ControlGetText(@GUI_WinHandle, "", @GUI_CtrlHandle)
        Case "Enable"
            ControlEnable(@GUI_WinHandle, "", $ctrlInput)
            ControlFocus(@GUI_WinHandle, "", $ctrlInput)
        Case "Disable"
            ControlDisable(@GUI_WinHandle, "", $ctrlInput)
    EndSwitch
EndFunc

Func _Mouse_L_Button($hWnd, $Msg, $wParam, $lParam)
    If $hWnd = $hGUI Then ConsoleWrite("Focus = " & ControlGetFocus($hWnd) & @LF)
EndFunc

You only get a response from the $WM_LBUTTONDOWN message when you click outside the input control.