GUI under start menu, on top of everything else

[theholycow]

As the title says, I want to have my gui run on top of everything, but still be able to access the taskbar and start menu. doable?

[Pain]

$WS_EX_TOPMOST or WinSetOnTop()?

[theholycow]

I tried both, they both put it on top of the taskbar too...

[smashly]

Hi,

I'd imagine youd have to write some form of custom function using GUIRegisterMsg(), WinActive, _WinAPI_GetWindowLong, _WinAPI_SetWindowLong, _WinAPI_SetWindowPos to set the window topmost and not topmost depending on the state of your window.

I could be wrong, but I don't think there is a magic set once window style that will accomplish what you need.

Cheers

[theholycow]

I was afraid of that... hmm ok. I am almost certainly not capable enough to do that right, so I'll try to find another way to make it work

[martin]

I was afraid of that... hmm ok. I am almost certainly not capable enough to do that right, so I'll try to find another way to make it work

It's not that difficult. You only need to use WinSetOnTop.

When you use WinSetOnTop for your gui it sets it to the top of course. If you then use WInSetOnTop again but forthe task bar then your gui will be second from the top and will not cover the task bar.

Here is a small example

#include <guiconstantsex.au3>
#include <Timers.au3>
$GUI = GUICreate("Window ", 300, 300, 300, 300)
GUISetState()
$WPos = WinGetPos($GUI)

WinSetOnTop($GUI, "", 1)
WinSetOnTop("[class:Shell_TrayWnd]", "", 1)
$topped = True

While 1
    If WinActive($GUI) And Not $topped Then
        WinSetOnTop("[class:Shell_TrayWnd]", "", 1)
        $topped = True
    Else
        $topped = False
    EndIf

    $m = GUIGetMsg()
    Switch $m
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    
WEnd

That has the disadvatage that if your gui is not active and then you drag it over the task bar it won't go behind the task bar until you let go of it. This can be solved by using a timer.

#include <guiconstantsex.au3>
#include <Timers.au3>
$GUI = GUICreate("Window ", 300, 300, 300, 300)
GUISetState()
$WPos = WinGetPos($GUI)

WinSetOnTop($GUI, "", 1)
WinSetOnTop("[class:Shell_TrayWnd]", "", 1)
$topped = True
_Timer_SetTimer($Gui,40,"topsy")
While 1
    

    $m = GUIGetMsg()
    Switch $m
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    
WEnd

Func Topsy($a,$b,$c,$d)
    If WinActive($GUI) And Not $topped Then
        WinSetOnTop("[class:Shell_TrayWnd]", "", 1)
        $topped = True
    Else
        $topped = False
    EndIf
    
EndFunc

Edited September 5, 2008 by martin

[theholycow]

Haha, and I just spent the last two hours trying to figure out how to do exactly that. I couldn't figure out how to specify the taskbar... thanks