_ArraySort_ByDelimitedItem UDF

[andybiochem]

Hi,

Just thought I'd share this - I use it quite a lot, thought it might be useful to someone.....nothing special really.

What it does:

Say you had an array of data looking like this:

12,123,33

23,43,123

45,55,323

3,443,4

74,46,88

99,102,9

....and you wanted to sort it low to high by reference to the 3rd item, to look like this:

3,443,4

99,102,9

12,123,33

74,46,88

23,43,123

45,55,323

You can use this UDF to do that.

UDF:

; #FUNCTION# ============================================================================
; Name...........: _ArraySort_ByDelimitedItem
; Description ...: Sorts delimited data by item reference
; Syntax.........: _ArraySort_ByDelimitedItem(ByRef $aArray,$cDelimiter,$iItem,$iDescending = 0)
; Parameters ....:  $aArray - Array of delimited data to sort
;                   $cDelimiter - delimiter character
;                   $iItem - data item to sort by
;                   $iDescending - 0=low to high, 1=high to low
; Notes..........: Requires <Array.au3>
; =======================================================================================
Func _ArraySort_ByDelimitedItem(ByRef $aArray,$cDelimiter,$iItem,$iDescending = 0)
    Local $aItems[UBound($aArray)][2]
    For $i = 1 To (UBound($aItems) - 1)
        $aItems[$i][0] = $aArray[$i]
        $aData = StringSplit($aArray[$i],$cDelimiter)
        $aItems[$i][1] = Number($aData[$iItem])
    Next
    _ArraySort($aItems,$iDescending,1,UBound($aItems) - 1,1)
    For $i = 1 to (UBound($aArray) - 1)
        $aArray[$i] = $aItems[$i][0]
    Next
EndFunc

Example useage:

expandcollapse popup

#include <Array.au3>

;----- create some random data to sort -----
Dim $Data[101]
For $i = 1 to 100
    $Data[$i] = Random(0,100,1) & "," & Random(0,100,1) & "," & Random(0,100,1)
Next

_ArrayDisplay($Data,"Data NOT sorted")

_ArraySort_ByDelimitedItem($Data,",",3,0)

_ArrayDisplay($Data,"Data sorted by 3rd item")



; #FUNCTION# ============================================================================
; Name...........: _ArraySort_ByDelimitedItem
; Description ...: Sorts delimited data by item reference
; Syntax.........: _ArraySort_ByDelimitedItem(ByRef $aArray,$cDelimiter,$iItem,$iDescending = 0)
; Parameters ....:  $aArray - Array of delimited data to sort
;                   $cDelimiter - delimiter character
;                   $iItem - data item to sort by
;                   $iDescending - 0=low to high, 1=high to low
; Notes..........: Requires <Array.au3>
; =======================================================================================
Func _ArraySort_ByDelimitedItem(ByRef $aArray,$cDelimiter,$iItem,$iDescending = 0)
    Local $aItems[UBound($aArray)][2]
    For $i = 1 To (UBound($aItems) - 1)
        $aItems[$i][0] = $aArray[$i]
        $aData = StringSplit($aArray[$i],$cDelimiter)
        $aItems[$i][1] = Number($aData[$iItem])
    Next
    _ArraySort($aItems,$iDescending,1,UBound($aItems) - 1,1)
    For $i = 1 to (UBound($aArray) - 1)
        $aArray[$i] = $aItems[$i][0]
    Next
EndFunc

Like I said, nothing much really, just makes sorting CSVs and the like a bit easier.

Ta!