Music Files

[Marlo]

Hey guys. I'm in the process of making a new AutoIt App but i've ran into a problem.

You see in my app i plan to use .mp3 files and most mp3 files have more than just a file name.

If you right click a music file, click properties then hit the "Summary" tab then click "Advanced" You will see artist information.

Example:

Now how would i go about getting this information into an autoit Variable/Array? i cant see anything in the help files =(

Any help at all is apreciated.

Regards

[torels]

try these

expandcollapse popup

Func Songinfo($file) ;Finds Title|Author|Album for any media file
    Dim $return[5]
    $return[1] = _GetExtProperty($file, 10);name
    $return[2] = _GetExtProperty($file, 16);atrist
    $return[3] = _GetExtProperty($file, 17);album
    
    If $return[1] = "" Or $return[1] = "Unknown" Then $return[1] = "No_name_" & Floor(Random(0, 1000))
    If $return[2] = "" Or $return[2] = "Unknown" Then $return[2] = "Unknown_Artist"
    If $return[3] = "" Or $return[3] = "Unknown" Then $return[3] = "Unknown_Album"
    
    Return $return
EndFunc   ;==>Songinfo

Func _GetExtProperty($sPath, $iProp)
    Local $iExist, $sFile, $sDir, $oShellApp, $oDir, $oFile, $aProperty, $sProperty
    $iExist = FileExists($sPath)
    If $iExist = 0 Then
        SetError(1)
        Return 0
    Else
        $sFile = StringTrimLeft($sPath, StringInStr($sPath, "\", 0, -1))
        $sDir = StringTrimRight($sPath, (StringLen($sPath) - StringInStr($sPath, "\", 0, -1)))
        $oShellApp = ObjCreate("shell.application")
        $oDir = $oShellApp.NameSpace($sDir)
        $oFile = $oDir.Parsename($sFile)
        If $iProp = -1 Then
            Local $aProperty[35]
            For $i = 0 To 34
                $aProperty[$i] = $oDir.GetDetailsOf($oFile, $i)
            Next
            Return $aProperty
        Else
            $sProperty = $oDir.GetDetailsOf($oFile, $iProp)
            If $sProperty = "" Then
                Return "Unknown"
            Else
                Return $sProperty
            EndIf
        EndIf
    EndIf
EndFunc   ;==>_GetExtProperty

cheers!

[Marlo]

Thanks, Worked perfectly