...

[stuka]

.

Edited August 24, 2009 by stuka

[SmOke_N]

Simple way... Label + GUIGetMsg() + ShellExecute()

[torels]

maybe change the color whent the mouse is over it

or change cursor

[torels]

no just do when mouse's x > label's x AND < (label's x + label's width) And mouse's y > label's y AND < (label's y + label's height) guictrlsetcolor($yourlabel, $somecolor)

[SmOke_N]

The easiest way IMO:

; A bit of effort, and some code goes a long way
$h_gui = GUICreate("My Gui")
$i_label_autoit_link = _GUICtrl_HyperLinkCreate("Click Me", 10, 10)
GUISetState()
While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $i_label_autoit_link
            _GUICtrl_HyperLinkExecute($i_label_autoit_link, "http://www.autoitscript.com/forum/index.php")
    EndSwitch
WEnd

Func _GUICtrl_HyperLinkCreate($s_text, $i_x, $i_y, $i_w = Default, $i_h = Default, $i_style = -1, $i_exstyle = -1)
    Local $i_ret = GUICtrlCreateLabel($s_text, $i_x, $i_y, $i_w, $i_h, $i_style, $i_exstyle)
    GUICtrlSetCursor(-1, 0)
    GUICtrlSetColor(-1, 0x0000FF)
    GUICtrlSetFont(-1, 9, 400, 4)
    Return $i_ret
EndFunc

Func _GUICtrl_HyperLinkExecute($i_ctrl, $s_url, $i_color = 0x6600CC)
    GUICtrlSetColor($i_ctrl, $i_color)
    Return ShellExecute($s_url)
EndFunc