Adding Array To Another Array ?

[komalo]

hi

i am simply returning an array from my function to another array but i can't use it

the example shows the problem

Local $ThemeBinary[15]

$ThemeBinary[0] = _ExampleReturn()
MsgBox("","",$ThemeBinary[0][1])

Func _ExampleReturn()
    Local $aReturn[4]
    $aReturn[0] = 1
    $aReturn[1] = 2
    $aReturn[2] = 3
    $aReturn[3] = 4
    Return $aReturn
EndFunc

[picaxe]

Local $ThemeBinary[15]

$ThemeBinary[0] = _ExampleReturn()
$aAry = $ThemeBinary[0]
MsgBox("","","$aAry[1]=" & $aAry[1])

Func _ExampleReturn()
    Local $aReturn[4]
    $aReturn[0] = 1
    $aReturn[1] = 2
    $aReturn[2] = 3
    $aReturn[3] = 4
    Return $aReturn
EndFunc

[Melba23]

komalo,

picaxe has fgiven you a valid solution, but I thought a bit more explanation might be useful.

With your example, you are putting the entire returned array (all 4 elements) into the first array of $aThemeBinary. Look at this code to see what I mean:

#include <Array.au3>

Local $aThemeBinary[15]

$aThemeBinary[0] = _ExampleReturn()

_ArrayDisplay($aThemeBinary, "$aThemeBinary")
_ArrayDisplay($aThemeBinary[0], "$aThemeBinary[0]")

Func _ExampleReturn()
    Local $aReturn[4]
    $aReturn[0] = 1
    $aReturn[1] = 2
    $aReturn[2] = 3
    $aReturn[3] = 4
    Return $aReturn
EndFunc

Then you are trying to use $ThemeBinary as a 2-D array in the MsgBox call which gives you the "Array variable has incorrect number of subscripts or subscript dimension range exceeded" error. If you want to resize $ThemeBinary to the same size as the returned array, then use this code:

#include <Array.au3>

Local $aThemeBinary[15]

$aThemeBinary = _ExampleReturn()

_ArrayDisplay($aThemeBinary, "$aThemeBinary")

Func _ExampleReturn()
    Local $aReturn[4]
    $aReturn[0] = 1
    $aReturn[1] = 2
    $aReturn[2] = 3
    $aReturn[3] = 4
    Return $aReturn
EndFunc

If you want to keep $aThemeBinary at its original size than you will have to change the code to this:

#include <Array.au3>

Local $aThemeBinary[15]

$aArray = _ExampleReturn()

For $i = 0 To UBound($aArray) - 1
    $aThemeBinary[$i] = $aArray[$i]
Next

_ArrayDisplay($aThemeBinary, "$aThemeBinary")

Func _ExampleReturn()
    Local $aReturn[4]
    $aReturn[0] = 1
    $aReturn[1] = 2
    $aReturn[2] = 3
    $aReturn[3] = 4
    Return $aReturn
EndFunc

If you want to keep all the returned array inside the first element of $aThemeBinary, then you have to go with picaxe's code and extract the returned elements into another array before using them:

#include <Array.au3>

Local $aThemeBinary[15]

$aThemeBinary[0] = _ExampleReturn()

$aArray = $aThemeBinary[0]

_ArrayDisplay($aThemeBinary, "$aThemeBinary")
_ArrayDisplay($aArray, "$aArray")

Func _ExampleReturn()
    Local $aReturn[4]
    $aReturn[0] = 1
    $aReturn[1] = 2
    $aReturn[2] = 3
    $aReturn[3] = 4
    Return $aReturn
EndFunc

I hope that clears up any confusion over what was happening. However, I would draw your attention to the following from the Help file:

"...an AutoIt-Array could also contain different types, even other Arrays...This has not been strictly forbidden in AutoIt. However, it is NOT ADVISABLE to mix different datatypes in an Array. Especially the use of an Array inside another Array will severely affect the execution speed of your script."

So be careful if you do decide you want to keep your returned array inside $aThemeBinary - it might come back to bite you!

Please ask if anything is unclear.

M23

[komalo]

thank you all

it's clear for me now Melba23

Edited February 4, 2009 by komalo