Date Style

[BattleOfMoonShae]

Could anyone tell me what the style number would be for the GUICtrlCreateDate

that would show the date in a 00/00/00 instead of 00/00/0000 and still show the calander. I went through the default -1 to 50 with no luck. Our main frame only excepts a six digit date.

Thanks in advance for your time.

#include <GUIConstants.au3>

   GUICreate("DUNNING INFORMATION", 320, 155, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1, 0x00000018)
   
   WinSetState("DUNNING INFORMATION -", "", @SW_SHOW)
   
   $Action=GUICtrlCreateDate ("", 10, 5, 300, 20, 12  )
;   $Action = GUICtrlCreateInput("Enter The Action Date", 10, 5, 300, 20)
   GUICtrlSetState(-1, $GUI_ACCEPTFILES)
   
   $Dun = GUICtrlCreateInput("Enter The Dun Number", 10, 35, 300, 20)
   GUICtrlSetState(-1, $GUI_ACCEPTFILES)
   
   $Dollar = GUICtrlCreateInput("Enter the Dollar Amount PD", 10, 65, 300, 20)
   GUICtrlSetState(-1, $GUI_ACCEPTFILES)
   
   $Add = GUICtrlCreateInput("Add Extra Comment - 60 Characters Max", 10, 95, 300, 20)
   GUICtrlSetState(-1, $GUI_ACCEPTFILES)
   
   $btn = GUICtrlCreateButton("PROCEED", 135, 125, 60, 20)
   GuiCtrlSetState($btn, $GUI_DEFBUTTON)
  ;GUICtrlSetState(-1,$GUI_FOCUS)       ; the focus is on this button
   GUISetState()
   $msg = 0
   While $msg <> $GUI_EVENT_CLOSE
      $msg = GUIGetMsg()
      Select
         Case $msg = $btn
            ExitLoop
      EndSelect
   WEnd

[Holger]

Just take a look at the helpfile ...

Ok, I have to say, at first I aslo didn't know where the problem could be.

But please take a look (if you have WindowsXP) under the Control Panel -> Region- and Language-Options (I think) -> Advanced or something like that on the Regional Settings-tab -> Date -> Short Dateformat !

Maybe this is set (by default I think) to "DD/MM/YYYY".

So long...

Edit: just forget:

You have to change your line:

$Action=GUICtrlCreateDate ("", 10, 5, 300, 20, 12)

to something like:

$Action=GUICtrlCreateDate ("", 10, 5, 300, 20,$DTS_SHORTDATEFORMAT)

Edited March 1, 2005 by Holger

[BattleOfMoonShae]

Just take a look at the helpfile ...

Ok, I have to say, at first I aslo didn't know where the problem could be.

But please take a look (if you have WindowsXP) under the Control Panel -> Region- and Language-Options (I think) -> Advanced or something like that on the Regional Settings-tab -> Date -> Short Dateformat !

Maybe this is set (by default I think) to "DD/MM/YYYY".

So long...

Edit: just forget:

You have to change your line:

$Action=GUICtrlCreateDate ("", 10, 5, 300, 20, 12)

to something like:

$Action=GUICtrlCreateDate ("", 10, 5, 300, 20,$DTS_SHORTDATEFORMAT)

<{POST_SNAPBACK}>

I tried that code already and it gives me the same date 00/00/0000 as the style 12 does. I need 00/00/00

[SlimShady]

It is possible. You can change the style to anything you like.

You need to send the DTM_SETFORMAT message to the date control using GUICtrlSendMsg.

About the format: check the MSDN page

About the value of the message: search for it on Google.com .

[Holger]

@SlimShady: great info

So it could looks like:

$DTM_SETFORMAT = 0x1005
$Action=GUICtrlCreateDate ("", 10, 5, 300, 20,$DTS_SHORTDATEFORMAT)
GUICtrlSendMsg(-1,$DTM_SETFORMAT,0,"dd.MM.yy")

[SlimShady]

I believe he wants it like this.

GUICreate('New GUI')
$DTM_SETFORMAT = 0x1005
$Action=GUICtrlCreateDate ("", 10, 5, 80, 20)
GUICtrlSendMsg(-1,$DTM_SETFORMAT,0,"MM/dd/yy")
GUISetState()
While 1
   $msg = GUIGetMsg()
   If $msg = -3 Then
      GUIDelete()
      EXIT
   EndIf
WEnd

[BattleOfMoonShae]

Thanks guys. That is exactly what I was looking for.

A golden Autoit OSCAR awarded to both of you.