Sign in to follow this  
Followers 0
Sathya

Enable and disable a edit box while selecting an option(radio button)

2 posts in this topic

#1 ·  Posted (edited)

Hi,

How to enable and disable a edit box while selecting an option using radio button.

For e.g. i have 2 radio buttons "A & B". If i select "A", few more radio buttons like "1,2,3..." shall be enabled and if i select "B" another set of radio buttons like "I, II, III..." shall be enabled.

Note: If i select "A" then options of "B" should be hidden.

Thanks in advance...

Sathya

Edited by Sathya

Share this post


Link to post
Share on other sites



Sathya,

Look at this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

GUICreate("Test", 300, 120)

GUICtrlCreateGroup ( "", 10, 10, 70, 70)
Opt("GUICoordMode",0); Relative coords
$hRadio_A = GUICtrlCreateRadio("A", 10, 20, 50, 20)
    GUICtrlSetState(-1, $GUI_CHECKED)
$hRadio_B = GUICtrlCreateRadio("B", -1, 20, 50, 20)
Opt("GUICoordMode",1); GUI coords

GUICtrlCreateGroup ( "", 100, 10, 70, 100)
Opt("GUICoordMode",0); Relative coords
$hRadio_1 = GUICtrlCreateRadio("1", 10, 20, 50, 20)
$hRadio_2 = GUICtrlCreateRadio("2", -1, 20, 50, 20)
$hRadio_3 = GUICtrlCreateRadio("3", -1, 20, 50, 20)
Opt("GUICoordMode",1); GUI coords

GUICtrlCreateGroup ( "", 200, 10, 70, 100)
    GUICtrlSetState(-1, $GUI_HIDE)
Opt("GUICoordMode",0); Relative coords
$hRadio_I = GUICtrlCreateRadio("I", 10, 20, 50, 20)
    GUICtrlSetState(-1, $GUI_HIDE)
$hRadio_II = GUICtrlCreateRadio("II", -1, 20, 50, 20)
    GUICtrlSetState(-1, $GUI_HIDE)
$hRadio_III = GUICtrlCreateRadio("III", -1, 20, 50, 20)
    GUICtrlSetState(-1, $GUI_HIDE)
Opt("GUICoordMode",1); GUI coords

GUISetState()

$fRadio_A_State = True

While 1

    If GUIGetMsg() = $GUI_EVENT_CLOSE Then Exit
    
    If BitAnd(GUICtrlRead($hRadio_A), $GUI_CHECKED) <> $fRadio_A_State Then
        $fRadio_A_State = Not $fRadio_A_State
        If $fRadio_A_State Then
            For $i = $hRadio_I - 1 To $hRadio_III
                GUICtrlSetState($i, $GUI_HIDE)
            Next
            For $i = $hRadio_1 - 1 To $hRadio_3
                GUICtrlSetState($i, $GUI_SHOW)
            Next
        Else
            For $i = $hRadio_1 - 1 To $hRadio_3
                GUICtrlSetState($i, $GUI_HIDE)
            Next
            For $i = $hRadio_I - 1 To $hRadio_III
                GUICtrlSetState($i, $GUI_SHOW)
            Next
        EndIf
    EndIf
WEnd

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0