text in combo box disappears

[sundeep]

Hi,

I have created a combo box initially("Which has no text string") and later use it again to display the filename selected.

But when I move the mouse curzor over the combo box, it removes the text momentarily and again redisplays after I minimize and maximize the GUI screen.

Code:

;INPUT

;$input = GuiCtrlCreateInput($file, 10, 50, 260, 20)

$input = GuiCtrlCreatecombo("", 10, 50, 260, 20)

;CHOOSE FILE

$choosebutton = GuiCtrlCreateButton ("File", 10, 80, 70, 20)

; BUTTON

$uploadbutton = GuiCtrlCreateButton("Upload", 105, 80, 70, 20)

$cancelbutton = GUICtrlCreateButton("Cancel", 202, 80, 70, 20)

GUISetState()

While 1

$msg = GUIGetMsg()

Select

Case $msg = $GUI_EVENT_CLOSE Or $msg = $cancelbutton

ExitLoop

Case $msg = $choosebutton

$file = FileOpenDialog("Choose file to upload...", "", "All (*.*)")

GuiCtrlCreatecombo($file, 10, 50, 260, 20)

[GEOSoft]

Because you are creating a new control instead of setting the data to the existing one

;INPUT
;$input = GuiCtrlCreateInput($file, 10, 50, 260, 20)
$input = GuiCtrlCreatecombo("", 10, 50, 260, 20)

;CHOOSE FILE
$choosebutton = GuiCtrlCreateButton ("File", 10, 80, 70, 20)
; BUTTON
$uploadbutton = GuiCtrlCreateButton("Upload", 105, 80, 70, 20)
$cancelbutton = GUICtrlCreateButton("Cancel", 202, 80, 70, 20)

GUISetState()

While 1
   $msg = GUIGetMsg()
   
   
   Switch $Msg
      Case $GUI_EVENT_CLOSE, $cancelbutton
         ExitLoop
      Case $choosebutton 
         $file = FileOpenDialog("Choose file to upload...", "", "All (*.*)")
        ;;  There should be some error checking added here
         GuiCtrlSetData($Input, $file) 
   EndSwitch
Wend

[Melba23]

Melba23,

You are recreating the combobox! Try using GUICtrlSetData instead (and if you then use the Combo UDF you can set the text as well :-) )

#include <GUIConstantsEx.au3>
#include <ComboConstants.au3>
#Include <GuiComboBox.au3>

GUICreate("Test", 500, 500)

$input = GUICtrlCreateCombo("", 10, 50, 260, 20)

;CHOOSE FILE
$choosebutton = GUICtrlCreateButton("File", 10, 80, 70, 20)
; BUTTON
$uploadbutton = GUICtrlCreateButton("Upload", 105, 80, 70, 20)
$cancelbutton = GUICtrlCreateButton("Cancel", 202, 80, 70, 20)

GUISetState()

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE Or $msg = $cancelbutton
            ExitLoop
        Case $msg = $choosebutton
            $file = FileOpenDialog("Choose file to upload...", "", "All (*.*)")
            GUICtrlSetData($input, $file)
            _GUICtrlComboBox_SetEditText($input, $file)
        EndSelect
WEnd

M23

P.S. Please try and post complete code - you do not make many friends by forcing us to add include files and close your loops!

P.P.S. Please use Code tags. Put [code ] before and [/code ] after your posted code (but omit the trailing space - it is only there so the tags display here).

Edit: Speeling!

Edited March 31, 2009 by Melba23

[sundeep]

Thanks a lot guys, Melba, Il make sure of following your suggestions from next time and a long time to come :-). This was my first post.

Cheers!

Sun.