using $var1.$var in expression

[eternaluxe]

I'm trying to do this, but can't figure the proper format:

$result = $result & $obj.$property

Here is the full script:

$wbemFlagReturnImmediately = 0x10
$wbemFlagForwardOnly = 0x20
$strComputer = "localhost"
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\CIMV2")
$thisComputerName = GetSpecificWMI("Name","Win32_ComputerSystem")

MsgBox(4096, "Computer name", $thisComputerName)

Func GetSpecificWMI($property, $class)
    $result = ""
    $specificObj = $objWMIService.ExecQuery("SELECT " & $property & " FROM " & $class & "", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    If isObj($specificObj) then
        For $obj In $specificObj
            $result = $result & $obj.$property
        Next
    EndIf
    Return $result
EndFunc

[nguyenbason]

What do you want to do? You are assigning value for $result that taking from WMI query?

You want to separate each value or what?

$result = $result & $obj.$property & "|"

[eternaluxe]

For example, in this instance $property = "Name"

Change the line inquestion to

$result = $result & $obj.Name

and it works, but

$result = $result & $obj.$property

doesn't.

[Crystall]

Hello.

I've found an solution for your problem. Check this out:

Func GetSpecificWMI($property, $class)
    $result = ""
    $specificObj = $objWMIService.ExecQuery("SELECT * FROM " & $class & "", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    If isObj($specificObj) then
        For $obj In $specificObj
            $result = $result & Execute("$obj." & Eval("property"))
        Next
    EndIf
    Return $result
EndFunc

EDIT: Enjoy this piece of code from Russia

Edited July 10, 2009 by Crystall

[eternaluxe]

Awesmoe! Thanks so much!