Problem with flickering +WinSetTrans

[monter]

I'd like to have a Always-On-Top semi-transparent GUI window. When I move the cursor over it - it should be solid. But it is ugly flickering effect. Below the code:

expandcollapse popup

#include <GUIConstants.au3>
Const $guiW = 400
Const $guiH = 200
$guiTitle = "Transparency & cursor hovering"
$myGUI = GUICreate($guiTitle, $guiW, $guiH)
$label = GUICtrlCreateLabel("How to avoid flickering when mouse is over the GUI?", 80, 20, 300, 17)
If @OSTYPE = "WIN32_WINDOWS" Then $xponly = GUICtrlCreateLabel("This works only in Win XP/2000.", 120, 40, 200, 17)
$combo = GUICtrlCreateCombo("but not set too long delay", 125, 60, 150, 100)
$comboItem = GUICtrlSetData(-1, "in Adlib function")
$edit = GUICtrlCreateEdit("I don't know. Anyone help?", 100, 100, 200, 50, $ES_READONLY)
$button = GUICtrlCreateButton("E&xit", 175, 160, 50, 25)

GUISetState(@SW_SHOW)
WinSetOnTop($guiTitle, "", 1)
AdlibEnable("HoverTrans")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _Exit()
        Case $button
            _Exit()
    EndSwitch
WEnd

Func HoverTrans()
    $hover = GUIGetCursorInfo()
    Select
        Case $hover[0] < 0 Or $hover[1] < 0 Or $hover[0] > $guiW Or $hover[1] > $guiH
            WinSetTrans($guiTitle, "", 160)
        Case Else
            WinSetTrans($guiTitle, "", 255)
    EndSelect
    
EndFunc  ;==>HoverTrans

Func _Exit()
    Exit
EndFunc  ;==>_Exit

[GaryFrost]

expandcollapse popup

#include <GUIConstants.au3>
Const $guiW = 400
Const $guiH = 200
$solid = 1
$guiTitle = "Transparency & cursor hovering"
$myGUI = GUICreate($guiTitle, $guiW, $guiH)
$label = GUICtrlCreateLabel("How to avoid flickering when mouse is over the GUI?", 80, 20, 300, 17)
If @OSTYPE = "WIN32_WINDOWS" Then $xponly = GUICtrlCreateLabel("This works only in Win XP/2000.", 120, 40, 200, 17)
$combo = GUICtrlCreateCombo("but not set too long delay", 125, 60, 150, 100)
$comboItem = GUICtrlSetData(-1, "in Adlib function")
$edit = GUICtrlCreateEdit("I don't know. Anyone help?", 100, 100, 200, 50, $ES_READONLY)
$button = GUICtrlCreateButton("E&xit", 175, 160, 50, 25)

GUISetState(@SW_SHOW)
WinSetOnTop($guiTitle, "", 1)
AdlibEnable("HoverTrans")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _Exit()
        Case $button
            _Exit()
    EndSwitch
WEnd

Func HoverTrans()
    $hover = GUIGetCursorInfo()
    Select
        Case $hover[0] < 0 Or $hover[1] < 0 Or $hover[0] > $guiW Or $hover[1] > $guiH
            If $solid Then
                $solid = 0
                WinSetTrans($guiTitle, "", 160)
            EndIf
        Case $solid = 0
            $solid = 1
            WinSetTrans($guiTitle, "", 255)
    EndSelect
    
EndFunc   ;==>HoverTrans

Func _Exit()
    Exit
EndFunc   ;==>_Exit

[monter]

$solid = 1
            If $solid Then
                $solid = 0
                WinSetTrans($guiTitle, "", 160)
            EndIf
        Case $solid = 0
            $solid = 1

Thank You very much!