Change label

[Meli90]

Hello!

How I can change the label after mouse move over it. Without click on it.

And the label come back to first appearance after mouse leave it.

Regard...

[Melba23]

Meli90,

Personally, I would use GUIGetCursorInfo to detect that the cursor was over the label and then change it (here I have changed the colour). I would also suggest using a flag as I have to prevent the flickering you would get were you to apply the change on every pass of the loop:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hLabel = GUICtrlCreateLabel("", 10, 10, 50, 50)
GUICtrlSetBkColor(-1, 0xFF0000)

GUISetState()

$fLabel = "Red"

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    $aInfo = GUIGetCursorInfo($hGUI)
    If $aInfo[4] = $hLabel And $fLabel = "Red" Then
        GUICtrlSetBkColor($hLabel, 0x00FF00)
        $fLabel = "Green"
    ElseIf $aInfo[4] <> $hLabel And $fLabel = "Green" Then
        GUICtrlSetBkColor($hLabel, 0xFF0000)
        $fLabel = "Red"
    EndIf

WEnd

M23

Edit: Welcome the Autoit forums, by the way!

Edited August 21, 2009 by Melba23