Sign in to follow this  
Followers 0
Lupo73

Move windows together

4 posts in this topic

I can't find how to do it. Is there a way to move 2 windows together? I'd like to drag a gui, move it and keep another gui in the same relative position.


SFTPEx, AutoCompleteInput_DateTimeStandard(), _ImageWriteResize()_GUIGraduallyHide(): some AutoIt functions.

Lupo PenSuite: all-in-one and completely free selection of portable programs and games.

DropIt: a personal assistant to automatically manage your files.

ArcThemALL!: application to multi-archive your files and folders.

Share this post


Link to post
Share on other sites



lupo73,

A pair of synchronised GUIs: :)

; Credit to MikeOsdx and GaryFrost for original code snippet

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI1 = GUICreate ("Test1", 150, 100, -1, -1)
GUISetState()

; Get position of GUI1 and set GUI2 coords
$aPos1  = WinGetPos($hGUI1)
$iX1 = $aPos1[0]
$iY1 = $aPos1[1]
$iX2 = $iX1 + 156
$iY2 = $iY1

$hGUI2 = GUICreate ("Test2", 150, 100, $iX2, $iY2)
GUISetState()

;Register move event
GUIRegisterMsg($WM_MOVE, "MY_WM_MOVE")

; Set dock flag
$Dock = 2

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

Func MY_WM_MOVE($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam
    If ($hWnd = $hGUI1) Or ($hWnd = $hGUI2) Then
        _SynchroGUIs($hGUI1, $hGUI2, $Dock, $iX1, $iX2, $iY1, $iY2)
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc  ;==>MY_WM_MOVE

Func _SynchroGUIs(ByRef $GUI1, ByRef $GUI2, ByRef $Dock, ByRef $iX1, ByRef $iX2, ByRef $iY1, ByRef $iY2)

    Local $aPos1 = WinGetPos($GUI1)
    Local $aPos2 = WinGetPos($GUI2)

    If (($aPos1[0] <> $iX1 Or $aPos1[1] <> $iY1) And BitAND(WinGetState($GUI1), 2) Or $Dock = 2) Then
        $iX1 = $aPos1[0]
        $iY1 = $aPos1[1]
        $iX2 = $aPos1[2] + $iX1
        $iY2 = $iY1
        WinMove($GUI2, "", $iX2, $iY2);, $aPos2[2], $aPos1[3])
        $Dock = 1
    ElseIf (($aPos2[0] <> $iX2 Or $aPos2[1] <> $iY2) And BitAND(WinGetState($GUI2), 2)) Then
        $iX2 = $aPos2[0]
        $iY2 = $aPos2[1]
        $iX1 = $aPos2[0] - $aPos1[2]
        $iY1 = $iY2
        WinMove($GUI1, "", $iX1, $iY1);, $aPos1[2], $aPos2[3])
    ElseIf ($aPos1[0] <> $iX1 Or $aPos1[1] <> $iY1) And BitAND(WinGetState($GUI1), 16) Then
        WinSetState($GUI2, "", @SW_MINIMIZE)
    ElseIf ($aPos2[0] <> $iX2 Or $aPos2[1] <> $iY2) And BitAND(WinGetState($GUI2), 16) Then
        WinSetState($GUI1, "", @SW_MINIMIZE)
    ElseIf ($aPos1[0] <> $iX1 Or $aPos1[1] <> $iY1) And BitAND(WinGetState($GUI1), 2) Then
        WinSetState($GUI2, "", @SW_RESTORE)
    ElseIf ($aPos2[0] <> $iX2 Or $aPos2[1] <> $iY2) And BitAND(WinGetState($GUI2), 2) Then
        WinSetState($GUI1, "", @SW_RESTORE)

    EndIf
EndFunc  ;==>_SynchroGUIs

You will need to play about with the coords to fit it to your GUIs of course. :)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

I can't find how to do it. Is there a way to move 2 windows together? I'd like to drag a gui, move it and keep another gui in the same relative position.

A simpler version where only one window follows the other

; *** Start added by AutoIt3Wrapper ***
#include <WindowsConstants.au3>
; *** End added by AutoIt3Wrapper ***
#AutoIt3Wrapper_Add_Constants=n
Global Const $WM_ENTERSIZEMOVE = 0x231, $WM_EXITSIZEMOVE = 0x232


$gp = GUICreate("main gui", 300, 300, 200, 200)
GUISetState()
$gs = GUICreate("dragged gui", 200, 150, 400, 400)
GUISetState()


Global $RelPos[2]
GUIRegisterMsg($WM_ENTERSIZEMOVE, "setrelpos")
GUIRegisterMsg($WM_MOVE, "followme")

While 1
    If GUIGetMsg() = -3 Then Exit
WEnd

Func followme($hW, $iM, $wp, $lp)

    If $hW <> $gp Then Return

    Local $xypos = WinGetPos($gp);use WingetPos rather than the values in $lP
    WinMove($gs, "", $xypos[0] - $RelPos[0], $xypos[1] - $RelPos[1])

EndFunc ;==>followme


;When the primary window starts moving we want to know the relative position of the secondary window.
Func SetRelPos($hW, $iM, $wp, $lp)

    If $hW <> $gp Then Return

    Local $gpp = WinGetPos($gp)
    Local $gsp = WinGetPos($gs)

    $RelPos[0] = $gpp[0] - $gsp[0]
    $RelPos[1] = $gpp[1] - $gsp[1]


EndFunc ;==>SetRelPos

Serial port communications UDF Includes functions for binary transmission and reception.printing UDF Useful for graphs, forms, labels, reports etc.Add User Call Tips to SciTE for functions in UDFs not included with AutoIt and for your own scripts.Functions with parameters in OnEvent mode and for Hot Keys One function replaces GuiSetOnEvent, GuiCtrlSetOnEvent and HotKeySet.UDF IsConnected2 for notification of status of connected state of many urls or IPs, without slowing the script.

Share this post


Link to post
Share on other sites

Thank you for them, that make what I need..


SFTPEx, AutoCompleteInput_DateTimeStandard(), _ImageWriteResize()_GUIGraduallyHide(): some AutoIt functions.

Lupo PenSuite: all-in-one and completely free selection of portable programs and games.

DropIt: a personal assistant to automatically manage your files.

ArcThemALL!: application to multi-archive your files and folders.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0