How to jump to the end of a text in an edit control?

[supersonic]

Hi!

I'm trying to jump to the end of the text in an edit control...

Is there a way to find the last character position or to set

the position of the cursor in an edit control?

I'm looking for a function like "_GUICtrlEdit_SetCurPos()"...

Greets,

-supersonic.

Edited November 10, 2009 by supersonic

[Melba23]

supersonic,

here you go:

#Include <GUIConstantsEx.au3>
#Include <GUIEdit.au3>
#Include <ScrollBarConstants.au3>
#Include <WindowsConstants.au3>

$sFile = RegRead('HKLM\SOFTWARE\AutoIt v3\AutoIt', 'InstallDir') & '\include\changelog.txt'

GUICreate('MyGUI', 400, 300)
$hEdit = GUICtrlCreateEdit('', 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
GUISetState()
$iEnd = FileGetSize($sFile)

_GUICtrlEdit_SetText($hEdit, FileRead($sFile))
_GUICtrlEdit_SetSel($hEdit, $iEnd, $iEnd)
_GUICtrlEdit_Scroll($hEdit, $SB_SCROLLCARET)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

M23

Edit: This works when you already have text in the edit - you just find out how much:

#Include <GUIConstantsEx.au3>
#Include <GUIEdit.au3>
#Include <ScrollBarConstants.au3>
#Include <WindowsConstants.au3>

$sFile = RegRead('HKLM\SOFTWARE\AutoIt v3\AutoIt', 'InstallDir') & '\include\changelog.txt'

GUICreate('MyGUI', 400, 300)
$hEdit = GUICtrlCreateEdit('', 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
GUISetState()

_GUICtrlEdit_SetText($hEdit, FileRead($sFile))

$iEnd = StringLen(GUICtrlRead($hEdit))

_GUICtrlEdit_SetSel($hEdit, $iEnd, $iEnd)
_GUICtrlEdit_Scroll($hEdit, $SB_SCROLLCARET)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Edited November 10, 2009 by Melba23

[supersonic]

Thank you!

Edited November 10, 2009 by supersonic

[jvanegmond]

You can also do it by sending Ctrl + End to the edit control with ControlSend.

[supersonic]

Cool idea! Works pretty well...

You can also do it by sending Ctrl + End to the edit control with ControlSend.