Save Memo

[tom35i]

Hey all

I am trying to save the contents of a memo to a text file.

the memo is created using the following

$hGUI = GUICreate("SOC", 600, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")

any able to help?

cheers

[Mat]

This?

#Include<WindowsConstants.au3>

$hGUI = GUICreate("SOC", 600, 322)
   $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 296, $WS_VSCROLL)
   GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")

   $hSave = GUICtrlCreateButton ("Save", 2, 300, 80, 20)

GUISetstate ()

While 1
   Switch GUIGetMsg ()
      Case -3
         Exit
      Case $hSave
         _Save (GUICtrlRead ($iMemo), $hGUI)
   EndSwitch
WEnd

Func _Save ($sText, $hParent)
   Local $sFile = FileSaveDialog ("Save memo...", @WorkingDir, "Text file (*.txt)|All files (*.*)", 18, "", $hParent)
   If @Error Then Return 0
   Local $hFile = FileOpen ($sFile, 2)
      FileWrite ($hFile, $sText)
   FileClose ($hFile)
   Return 1
EndFunc ; ==> _Save

Mat