Sign in to follow this  
Followers 0
cynapse

TaskBar / TrayIcon

3 posts in this topic

Hi!

i have a GUI AutoIT software and i'd like to hide the taskbar to only have a trayicon (with a menu to show/hide).

When i'll click on "-", it will hide the software to the tray icon and when i will click on "x", it will close the software.

Could you help me please ?

I have already try to search information on the board but i was rather complicated..

Thanks for your support :-)

Cyn'

Share this post


Link to post
Share on other sites



cynapse,

Is this more understandable? :)

#include <GUIConstantsEx.au3>

Opt("TrayOnEventMode", 1) ; Use event trapping for tray menu
Opt("TrayMenuMode", 3) ; Default tray menu items will not be shown.

TrayCreateItem("Show")
TrayItemSetOnEvent(-1, "Tray_Show")
TrayCreateItem("Hide")
TrayItemSetOnEvent(-1, "Tray_Hide")
TrayCreateItem("Exit")
TrayItemSetOnEvent(-1, "On_Exit")

TraySetState()

; Make GUI a child of the hidden Autoit window - then it has no taskbar button
$hGUI = GUICreate("Test", 500, 500, -1, -1, -1, -1, WinGetHandle(AutoitWinGetTitle()))

GUISetState()

While 1

    Switch GUIGetMsg()
        ; Click [X]
        Case $GUI_EVENT_CLOSE
            Exit
        ; Click [_]
        Case $GUI_EVENT_MINIMIZE
            ; Hide as well as minimize
            GUISetState(@SW_HIDE, $hGUI)
    EndSwitch

WEnd

Func Tray_Show()
    ; Show and also restore in case it was minimized
    GUISetState(@SW_SHOW, $hGUI)
    GUISetState(@SW_RESTORE, $hGUI)
EndFunc

Func Tray_Hide()
    GUISetState(@SW_HIDE, $hGUI)
EndFunc

Func On_Exit()
    Exit
EndFunc

M23

1 person likes this

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

whowwwwww !!! what a quick answer !

that's perfect!

Thanks for your reactivity !!!

Have a good day !

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0