Sign in to follow this  
Followers 0
AuToItItAlIaNlOv3R

Tray icon

2 posts in this topic

Hi to all, i would like to set my program on trayicon when is pressed minimize button.

For example I've this try code

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Try", 116, 26, 268, 227)
$Label1 = GUICtrlCreateLabel("This is a test", 24, 8, 63, 17)
GUISetState(@SW_SHOW)
Opt("TrayMenuMode", 1)
Opt("TrayOnEventMode",1)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_MINIMIZE
            Minimize()

    EndSwitch
WEnd

Func Minimize()
GUISetState(@SW_HIDE)
TraySetState(1)
$Ripristina = TrayCreateItem("resume")
TrayItemSetOnEvent(-1,"resume")
$Escitray = TrayCreateItem("exit")
TrayItemSetOnEvent(-1,"exits")
EndFunc

Func resume()
GUISetState(@SW_SHOW)
EndFunc 

Func exits()
exit
endfunc

But when i minimize and then i resume the program, the tray menu is doubles, this is a photo :

Posted Image

How can i fix it? Sorry for my bad english, but it isn't my native language.

Hi!

Share this post


Link to post
Share on other sites



AuToItItAlIaNlOv3R,

You need to create the menu only once and then prevent it showing when the GUI is visible:

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Opt("TrayMenuMode", 3)
Opt("TrayOnEventMode", 1)
$Ripristina = TrayCreateItem("resume")
TrayItemSetOnEvent(-1, "resume")
$Escitray = TrayCreateItem("exit")
TrayItemSetOnEvent(-1, "exits")
TraySetClick(0)

$Form1 = GUICreate("Try", 116, 26, 268, 227)
$Label1 = GUICtrlCreateLabel("This is a test", 24, 8, 63, 17)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_MINIMIZE
            Minimize()
    EndSwitch
WEnd

Func Minimize()
    GUISetState(@SW_HIDE)
    TraySetState(1)
    TraySetClick(16)
EndFunc   ;==>Minimize

Func resume()
    GUISetState(@SW_SHOW)
    GUISetState(@SW_RESTORE)
    TraySetClick(0)
EndFunc   ;==>resume

Func exits()
    Exit
EndFunc   ;==>exits

I have made a few other changes (and used Tidy to make it look nice! :evil: ) - Please ask if anything is unclear. ;)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0