Func : Auto click around dictrict begin with Mouse positions

[forestfair]

Hi all!

I want to write a function to auto click in mspaint.exe

- first, i have 2 Variable :

+ 1: $positions of mouse

+ 2: $Radius : Radius of circle with point is positions of mouse

- when i click (or press {F10} to begin script) : it auto click (left) around positions of mouse to make a circle

EX : i have mouse positions : x=0,y=0, Radius of circle : r=10

- when script run : it'll make a circle in paint P(0,0) ,r = 10

Positions of all click is :

$x=0;$y=0

$r=10

while $x <= $r

$x=$x+1

wend

while $y <= $r

$y=$y+1

wend

..... i can't contionous

Regard !

Edited December 18, 2009 by forestfair

[Melba23]

forestfair,

Welcome to the AutoIt forum.

Do they no longer teach basic maths at school?

expandcollapse popup

#include <Misc.au3>

; Allows you to exit before the drawing ends if you so wish
HotKeySet("{ESC}", "On_Exit")

; Open paint if it not already open
If Not ProcessExists("mspaint.exe") Then
    Run("mspaint.exe")
    ProcessWait("mspaint.exe")
EndIf

; Set mouse coords to active window client area
Opt("MouseCoordMode", 2)

; Declare variables
$pi = 3.14159265358979
$nRadius = 10
$nStep = ($pi)/($nRadius * 4)

; Open dll for _IsPressed
$UserDLL = DllOpen("user32.dll")

Sleep(5000)

; Wait until mouse button pressed
While Not _IsPressed("01", $UserDLL)
    Sleep(10)
WEnd

; Get mouse position
$aMouse_Pos = MouseGetPos()
$iX = $aMouse_Pos[0]
$iY = $aMouse_Pos[1]

; Draw circle
For $i = 0 to 2 * $pi Step $nStep
    MouseClick("left", $iX + ($nRadius * Sin($i)), $iY + ($nRadius * Cos($i)))
Next

; Close dll for _IsPressed
DllClose($UserDLL)

Func On_Exit()
    Exit
EndFunc

Ask if anything is unclear.

M23

Edit: Pressed Post too soon!

Edited December 18, 2009 by Melba23