Child GUI Issue, please help.

[Gui]

Aye guys, I have a main GUI. Then, when a menu item is pressed, I want a child GUI to show. Then, when stuff is inserted into the child GUI, I want it to close from $GUI_EVENT_CLOSE. So far, it only closes is the main GUI is closed. I just want the child GUI to close when it's exit is pressed, and the mains to exit when it's pressed.

While 1
  $nMsg = GUIGetMsg (1)
    Switch $nMsg[1]
        Case $Form1
            Switch $nMsg[0]

                Case $GUI_EVENT_CLOSE
                    Exit
                Case $start
                    start()
                Case $credits
                    MsgBox(0,'Credits','Made by Henry.')
                Case $exit
                    Exit
            EndSwitch
        Switch $nMsg[0]
            Case $login
                GUICreate("Login Details.", 200, 110, -1, -1, Default, BitOR ($WS_EX_MDICHILD, $WS_EX_TOOLWINDOW), $Form1)          
                $user = GUICtrlCreateInput('Email',5,5,150,21)
                $pass = GUICtrlCreateInput('Password',5,30,150,21)
                $savedata = GUICtrlCreateButton('Save Data and Close',25,55,140,25)
                GUISetState(@SW_SHOW)
            Case $GUI_EVENT_CLOSE
            
                
        EndSwitch
    EndSwitch
WEnd

So far , I've tried alot. This is the furthest I've come to. They only close if the main's $GUI_EVENT_CLOSE is pressed.

GUI.

[Melba23]

Gui,

Here is one way to do it:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#include <Array.au3>
#include <ArrayDisplayEx.au3>


$Form1 = GUICreate("Test", 500, 500)

Global $mFile_Menu = GUICtrlCreateMenu("&File")
Global $login = GUICtrlCreateMenuItem("&Log In", $mFile_Menu)
Global $start = GUICtrlCreateMenuItem("&Start", $mFile_Menu)
Global $credits = GUICtrlCreateMenuItem("&Credits", $mFile_Menu)
Global $exit = GUICtrlCreateMenuItem("&Exit", $mFile_Menu)

GUISetState()

While 1

    Switch GUIGetMsg()

        Case $GUI_EVENT_CLOSE, $exit
            Exit
        Case $start
            ;start()
        Case $credits
            MsgBox(0, 'Credits', 'Made by Henry.')
        Case $login

            $Form2 = GUICreate("Login Details.", 200, 110, -1, -1, Default, BitOR($WS_EX_MDICHILD, $WS_EX_TOOLWINDOW), $Form1)
            $user = GUICtrlCreateInput('Email', 5, 5, 150, 21)
            $pass = GUICtrlCreateInput('Password', 5, 30, 150, 21)
            $savedata = GUICtrlCreateButton('Save Data and Close', 25, 55, 140, 25)
            GUISetState(@SW_SHOW)

            While 1

                $aMsg = GUIGetMsg(1)

                If $aMsg[1] = $Form2 Then ; Check we are getting messages from the child
                    Switch $aMsg[0]
                        Case $GUI_EVENT_CLOSE
                            GUIDelete($Form2)
                            ExitLoop
                        Case $savedata
                            ; Save data code goes here
                            MsgBox(0, "", "Simulating saving data")
                            GUIDelete($Form2)
                            ExitLoop
                    EndSwitch
                EndIf

            WEnd

    EndSwitch

WEnd

Ask if anything is unclear.

M23

P.S. It really helps if you post which does not not need a whole bunch of stuff added to make it run!

[Gui]

Thanks a bunch dude! <3. And i'll remember that next time.