Binary to DLLStruct

[Synchro]

I'd like to convert a Binary variable, such as returned by RegRead() for a REG_BINARY entry, into a DLLStruct. I can do it by using a bunch of BinaryMid() and DllStructSetData() calls, but I'm hoping there is a way to simply copy the entire structure from a Binary variable to an appropriately formatted DLLStruct.

I'm looking for an elegant way to convert a registry Time Zone Info field (e.g. HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Time Zones\Eastern Standard Time\TZI) into data that can be passed to _Date_Time_SetTimeZoneInformation().

Thanks.

[ProgAndy]

You can create the DLLStruct first. Then create a second DLLStruct as a byte-array on the pointer of the first struct and set the binary data to it. Now you can free the second struct again (does not free memory since it wasn't allocated by DLLStructCreate) and the data can be accessed from the first struct.

[Synchro]

Thanks for the pointer.

Here is the code in case anyone else can use it...

expandcollapse popup

SetTimeZone("Eastern Standard Time")

; Set the time zone
Func SetTimeZone($name)
    ; The Registry key of the Time Zones collection
    Const $tzKey = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Time Zones\"
    ; The Registry TZI field structure
    Const $tagTZI = "align 2; long Bias; long StdBias; long DayBias; BYTE StdDate[16]; BYTE DayDate[16]"        

    ; Create the data structures
    $tzi = DllStructCreate($tagTZI)
    $stdDate = DllStructCreate($tagSYSTEMTIME)
    $dayDate = DllStructCreate($tagSYSTEMTIME)

    ; Read the registry data
    $binTzi = RegRead($tzKey & $name, "TZI")
    $dayName = RegRead($tzKey & $name, "Dlt")
    $stdName = RegRead($tzKey & $name, "Std")
    
    ; Copy the binary TZI data to the TZI structure
    $tmp = DllStructCreate("BYTE[44]", DllStructGetPtr($tzi))
    DllStructSetData($tmp, 1, $binTzi)
    
    ; Get the integer data
    $bias = DllStructGetData($tzi, "Bias")
    $stdBias = DllStructGetData($tzi, "StdBias")
    $dayBias = DllStructGetData($tzi, "DayBias")
    
    ; Get the SYSTEMTIME data
    $tmp = DllStructCreate("BYTE[16]", DllStructGetPtr($stdDate))
    DllStructSetData($tmp, 1, DllStructGetData($tzi, "StdDate"))
    $tmp = DllStructCreate("BYTE[16]", DllStructGetPtr($dayDate))
    DllStructSetData($tmp, 1, DllStructGetData($tzi, "DayDate"))
    $tmp = 0

    ; Set the current time zone
    _Date_Time_SetTimeZoneInformation($bias, $stdName, $stdDate, $stdBias, $dayName, $dayDate, $dayBias)
EndFunc

[UEZ]

Thanks for the pointer.

Here is the code in case anyone else can use it...

Thanks very much! I avoided to reinvent the wheel for the usage of _Date_Time_SetTimeZoneInformation() function!

With trancexx' and your function I was able to write a script that can change the timezone on Windows Server 2008!

BR,

UEZ

Edited May 10, 2010 by UEZ