wait until in function whil script continues

[Rex]

Is this possible ?

I have a main gui, and several child gui's in my script.

Some of the child gui handles some input and so.

What i need is to pause a function until a child gui windows closes, but without pausing the entire script.

for now i do something like this.

GuiSetState(@SW_SHOW, $ChildGUI)
winactivate($ChildGUI, "") ; Child contains some inputboxes and an activation button and an exit button
_Function()


Func _Funftion()
winwaitclose($ChildGUI, "")
msgBox(16, "Msg", "Msg")
EndFunc

My problem is that the winwaitclose pauses the entire script, so the user can not use the buttons in the childGUI

I did try to put in a do until, and a while 1 wend and the all blocks the use of the child gui

Is there any way to do this, or do i have to loop forth and back until the child is closed?

Cheers

/Rex

[PsaltyDS]

Switch your script to GuiOnEventMode. The events actions will interrupt most things like WinWaitClose().

[Melba23]

Rex,

Without sight of the code proper, this is only a SWAG.

You could use an Adlib function to check if the window still exists:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hLabel = GUICtrlCreateLabel("", 10, 10, 100, 20)
$hButton = GUICtrlCreateButton("Child", 10, 50, 80, 30)

GUISetState()

While 1

    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $hGUI
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $hButton
                    $hChild = GUICreate("Child", 200, 100, 100, 100)
                    GUISetState()
                    AdlibRegister("_Check_Child")
            EndSwitch
        Case Else
            If $aMsg[0] = $GUI_EVENT_CLOSE Then GUIDelete($hChild)
    EndSwitch

WEnd

Func _Check_Child()

    If Not WinExists($hChild) Then
        MsgBox(0, "Child", "No longer there!")
        AdlibUnRegister("_Check_Child")
    EndIf

EndFunc

Ask if anything is unclear.

M23

[Rex]

Switch your script to GuiOnEventMode. The events actions will interrupt most things like WinWaitClose().

I always run in Guioneventmode , but still the winwait ect. still blocks until i do a hardkill

Cheers

/Rex

[PsaltyDS]

I always run in Guioneventmode , but still the winwait ect. still blocks until i do a hardkill

No it doesn't:

#include <GuiConstantsEx.au3>

Opt("GuiOnEventMode", 1)

$hGUI = GUICreate("Test", 300, 300)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Quit")
GUICtrlCreateButton("ONE", 100, 100, 100, 30)
GUICtrlSetOnEvent(-1, "_ButtonHit")
GUICtrlCreateButton("TWO", 100, 150, 100, 30)
GUICtrlSetOnEvent(-1, "_ButtonHit")
GUISetState()

_WaitForIt()

Func _WaitForIt()
    WinWaitClose($hGUI)
    MsgBox(64, "Closed", "Window Closed")
EndFunc

Func _Quit()
    GUIDelete($hGUI)
EndFunc

Func _ButtonHit()
    Local $sText = ControlGetText($hGUI, "", @GUI_CtrlId)
    MsgBox(64, "Button Hit", "You clicked: " & $sText)
EndFunc

The code you posted does not use event mode. Post a demo where you use event mode and get blocking.

[Rex]

Rex,

Without sight of the code proper, this is only a SWAG.

You could use an Adlib function to check if the window still exists:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hLabel = GUICtrlCreateLabel("", 10, 10, 100, 20)
$hButton = GUICtrlCreateButton("Child", 10, 50, 80, 30)

GUISetState()

While 1

    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $hGUI
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $hButton
                    $hChild = GUICreate("Child", 200, 100, 100, 100)
                    GUISetState()
                    AdlibRegister("_Check_Child")
            EndSwitch
        Case Else
            If $aMsg[0] = $GUI_EVENT_CLOSE Then GUIDelete($hChild)
    EndSwitch

WEnd

Func _Check_Child()

    If Not WinExists($hChild) Then
        MsgBox(0, "Child", "No longer there!")
        AdlibUnRegister("_Check_Child")
    EndIf

EndFunc

Ask if anything is unclear.

M23

Hi Melba

i think that this is eact what i need for my prog.

Did't new that that func existed thru i did a help file search before posting

I will try to put it into my code, and then repost tomorrow when i have tryed it a bit

Cheers

/Rex

[Rex]

Have one Q.

In the adlib...("func") how do i add extra options to load in function

eg.

func _Func($1, $2)

endfunc

cant finde any info in help file either.

Cheers

/Rex

[Melba23]

rex,

What i need is to pause a function until a child gui windows closes, but without pausing the entire script

child gui handles some input and so

Adlib lets you run your main script and interrupts at intervals. It could check whether there is any input in the child window, but as I said at the beginning, without sight of some code this is all guesswork. Give us some concrete details of what you want the child to do and what your main script is doing while waiting. Then we can see what might work.

M23

[Rex]

rex,

Adlib lets you run your main script and interrupts at intervals. It could check whether there is any input in the child window, but as I said at the beginning, without sight of some code this is all guesswork. Give us some concrete details of what you want the child to do and what your main script is doing while waiting. Then we can see what might work.

M23

The Adlib.. works as a charm

My q was only becorse i did't wanned to make a var global, but insted send the var's result to the function )

Like _Func("data")

Func _Func($Data)

Somthing here

endfunc

But i can't find out how to put the ("Data") in the adlib func call

Cheers

/Rex

[Melba23]

Rex,

But i can't find out how to put the ("Data") in the adlib func call

Af far as I know, you cannot pass parameters to an Adlib function - which is why you cannot find out how do do it! Looks like Global will have to do.

I did find this UDF which allows you to pass parameters to a function which is called at intervals. I have never used it, so I have no idea if it works well, but you might find it useful.

M23

[Rex]

Rex,

Af far as I know, you cannot pass parameters to an Adlib function - which is why you cannot find out how do do it! Looks like Global will have to do.

I did find this UDF which allows you to pass parameters to a function which is called at intervals. I have never used it, so I have no idea if it works well, but you might find it useful.

M23

Yes the globals it was )

The udf looks cool, but i recall somthing about the adlib-en/dis-able was removed and replaced by adlib-reg/unreg, thoe i only skimmed the code of the udf.

Cheers

/Rex