_GUICtrlButton_Create and GUIGetCursorInfo don't work

[chipDE]

Hi,

I have a problem with _GUICtrlButton_Create and GUIGetCursorInfo. I have more than one GUI and create buttons with _GUICtrlButton_Create in a Func. With a middle mouse button click then I'll get with GUIGetCursorInfo the Control ID. But the ID is always 0. But if I use GUICtrlCreateButton I get the correct ID.

Is there an alternative to GUIGetCursorInfo that works with _GUICtrlButton_Create?

Edited February 26, 2010 by chipDE

[Melba23]

chipDE,

You will not get a ControlID becasue those are internal AutoIt IDs returned to the user when the control is created . When you use the _GUICtrl* functions, you get a handle as a return value - i.e. the unique Windows indentifier for that window. As AutoIt did not create the control in question, it does not have ControlID to return to you when you use GUIGetCursorInfo. I hope that is clear.

To indentify a non-Autoit window from its location, you need to use _WinAPI_WindowFromPoint like this:

#include <GUIConstantsEx.au3>
#Include <WinAPI.au3>
#Include <GuiButton.au3>

Global $tPoint = DllStructCreate("int X;int Y")

$hGUI = GUICreate("Test", 500, 500)

$hButton = _GUICtrlButton_Create($hGUI, "Button", 10, 10, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_SECONDARYDOWN ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< right button on this example
            DllStructSetData($tPoint, "X", MouseGetPos(0))
            DllStructSetData($tPoint, "Y", MouseGetPos(1))
            $hWnd = _WinAPI_WindowFromPoint($tPoint)
            MsgBox(0, "", "Button = " & $hButton & @CRLF & "Window = " & $hWnd)

    EndSwitch

WEnd

But why are you using the _GUICtrl functions anyway?

M23