Map key to button

[Zych]

Hello,

I am almost finished with my script. However I would like to map the enter key, when the program is in focus, to a button. I see that when you set a hotkey, it maps a key or keys to a function, which is not what I want (unless I need to make a functions that simulates pressing the button I want).

When the person fills in his/her info and hits enter, I would like the program to see this as hitting one of my buttons (in this case a login button). Is this easy to do?

Thanks,

Zych

[kaotkbliss]

At that spot in your script where you want to check if enter is pressed, you could use _ispressed

[Melba23]

Zych,

Is this easy to do?

Yes!

Go and look at GUISetAccelerators in the Help file. This function lets you map keys to existing controls in your script like this:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hInput = GUICtrlCreateInput("", 10, 10, 480, 20)

$hLabel = GUICtrlCreateLabel("", 10, 50, 480, 20)

$hButton = GUICtrlCreateButton("Paste", 10, 90, 80, 30)

GUISetState()

; Set accelerators for Enter
Dim $AccelKeys[1][2]=[["{ENTER}", $hButton]]
GUISetAccelerators($AccelKeys)

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            GUICtrlSetData($hLabel, GUICtrlRead($hInput))
    EndSwitch

WEnd

As you can see, both the button and the "Enter" key put the contents of the input in the label.

M23

[Zych]

Very cool. This was very clever of them since I can re-set the accelerators later to have enter affect a different button. This is working out better than I thought it would. Again thank you!