Disable Combobox

[Rodger]

Hello,

I have the following combobox:

$hPCMStatusComboBox = _GUICtrlComboBox_Create ($GUI,"", 10, 515, 300, 35)

If want to disable it, I do:

GUICtrlSetState(_WinAPI_GetDlgCtrlID($hPCMStatusComboBox),$GUI_DISABLE)

but the combobox isn't disabled.

Why isn't the combobox disabled?

Thx,

Rodger

[Melba23]

Rodger,

It is often asking for tears at bedtime if you try and mix built-in commands (which need ControlIDs) and UDF created controls (which return handles). Use this instead - it works for me:

WinSetState($hPCMStatusComboBox, "", @SW_DISABLE)

M23

[somdcomputerguy]

Do you have #Include <WinAPI.au3> at the beginning of your script?

[Rodger]

Rodger,

It is often asking for tears at bedtime if you try and mix built-in commands (which need ControlIDs) and UDF created controls (which return handles). Use this instead - it works for me:

WinSetState($hPCMStatusComboBox, "", @SW_DISABLE)

M23

Thank you very much!!!

It Works !!

[somdcomputerguy]

I was going to suggest similar to what Melba23 said, but I read in the help file that _WinAPI_GetDlgCtrlID returns an ID, that WinSetState needs. The fact that using _WinAPI_GetDlgCtrlID in this case seems irrelevant to me is beside the point though.

[Yoriz]

I've had similar problem when creating a listview from the udf that i wanted to show,hide,enable and disable.

I ended up using from the following from WinAPI.au3 which gives another way of doing it using the Hwnd rather then the controlID.

_WinAPI_EnableWindow($hWnd, False) ; Disabled
_WinAPI_EnableWindow($hWnd, True) ; Enabled
_WinAPI_ShowWindow($hWnd, @SW_HIDE) ; Hiden
_WinAPI_ShowWindow($hWnd, @SW_SHOW) ; Shown

[Melba23]

snowmaker,

When the UDF creates the combo, it allocates a CtrID using the UDFGlobalID.au3 include file. This number is allocated by Windows and is very different from the internal ControlID used by AutoIt to identify its own controls - as you can see here:

#include <GUIConstantsEx.au3>
#Include <GuiComboBox.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 500, 500)

$hDummy = GUICtrlCreateDummy()
ConsoleWrite("AutoIt ControlID: " & $hDummy & @CRLF)

$hCombo = _GUICtrlComboBox_Create($hGUI, "", 10, 10, 200, 20)

$iCtrlID = _WinAPI_GetDlgCtrlID($hCombo)
ConsoleWrite("UDF CtrlID: " & $iCtrlID & @CRLF)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

So using the returned CtrlID value is useless in a built-in command which expects an AutoIt ControlID.

Gets confusing sometimes, doesn't it.

M23

[iresolver]

can you disable an item listed in the combo box?