Pointer to a struct Type, or pointer to a pointer?

[JRowe]

My questions is this: I have a dllCall expecting a struct to be passed. The struct is 3 separate floats, not arrays. I build them like so:

Local $StartVectorStruct = DllStructCreate("float;float;float")
    DllStructSetData($StartVectorStruct, 1 , $a_StartVector[0])
    DllStructSetData($StartVectorStruct, 2 , $a_StartVector[1])
    DllStructSetData($StartVectorStruct, 3 , $a_StartVector[2])

My question is this: when I pass it to the DllCall, do I want to pass ptr* or float* to pass the struct? or is it just a ptr?

;This
DllCall($_irrDll, "none:cdecl", "IrrGetCollisionPoint", "float*", DllStructGetPtr($StartVectorStruct))
;Or This...
DllCall($_irrDll, "none:cdecl", "IrrGetCollisionPoint", "ptr*", DllStructGetPtr($StartVectorStruct))
;Or even this?
DllCall($_irrDll, "none:cdecl", "IrrGetCollisionPoint", "ptr", DllStructGetPtr($StartVectorStruct))

Also, what is the reason for struct indices starting at 1, instead of 0?

Edited May 3, 2010 by JRowe

[bo8ster]

I would say the third one since DllStructGetPtr returns a pointer to a structure. Regardless of your intent you have created a structure then sending it in, the help file specifes the same thing but with ints.

float* is a pointer to a float which DllStructGetPtr does not return.

ptr* is a pointer to a pointer which would mean DllStructGetPtr would have to return a ponter to another pointer for that to be valid.

As for the second question, pass

DllCall($_irrDll, "none:cdecl", "IrrGetCollisionPoint", "float*", DllStructGetPtr($StartVectorStruct, 1))

This might work also for the first element within the structure.

[JRowe]

Cool - I went with the third one in the end, but it started to get pretty funky for a while. Thanks!

[trancexx]

I'm confused

What is the description for IrrGetCollisionPoint? What's expected for the parameter to be?

[JRowe]

integer = IrrGetCollisionPoint ( start as IRR_VECTOR, line_end as IRR_VECTOR, collision group as irr_selector, collision point as IRR_VECTOR )

The actual code I ended up with is:

Func _IrrGetCollisionPoint($a_StartVector, $a_EndVector, $h_CollisionGroup)
    Local $StartVectorStruct = DllStructCreate("float;float;float")
    DllStructSetData($StartVectorStruct, 1, $a_StartVector[0])
    DllStructSetData($StartVectorStruct, 2, $a_StartVector[1])
    DllStructSetData($StartVectorStruct, 3, $a_StartVector[2])
    Local $EndVectorStruct = DllStructCreate("float;float;float")
    DllStructSetData($EndVectorStruct, 1, $a_EndVector[0])
    DllStructSetData($EndVectorStruct, 2, $a_EndVector[1])
    DllStructSetData($EndVectorStruct, 3, $a_EndVector[2])

    Local $CollisionVectorStruct = DllStructCreate("float;float;float")
    DllCall($_irrDll, "none:cdecl", "IrrGetCollisionPoint", "ptr", DllStructGetPtr($StartVectorStruct), "ptr", DllStructGetPtr($EndVectorStruct), "ptr", $h_CollisionGroup, "ptr", DllStructGetPtr($CollisionVectorStruct))
    Local $result[3] = [DllStructGetData($CollisionVectorStruct, 1), DllStructGetData($CollisionVectorStruct, 2), DllStructGetData($CollisionVectorStruct, 3)]
    Return $result
EndFunc

An AutoIt version of a vector, then, would just be an array of 3 floats.

edit: 0.o

Looks like I have some revising to do.

Edited May 3, 2010 by JRowe

[trancexx]

edit: 0.o

Looks like I have some revising to do.

That looks better now to me.