How to get "word" from edit's caret position??

[piterek]

Hi!

A simple question is:

How to get "word" from edit's caret position??

Example:

- I have some text in notepad ("word1 word2 word3 word4...")

Now I set caret position somewhere inside "word2", and I want return from control only this "word2"

It's something like use ControlCommand function with "GetSelected", "" but I want return text without marking word

This function was used eg. AutoIt3 FuncPopUp

[Jos]

FuncPopUp is using some SciTE Director calls to get the word at the cursors active location and cannot easily be copied to notepad.

[Melba23]

piterek,

Here is a way to do it:

#Include <GuiEdit.au3>

; Start Notepad and enter some text, then start script

; Wait for Notepad to be active
WinWaitActive("[CLASS:Notepad]")
; Get handle for Edit control
$hNotePadEdit = ControlGetHandle("[CLASS:Notepad]", "", "[CLASS:Edit; INSTANCE:1]")

; Where is caret?
$aCaretPos = _GUICtrlEdit_GetSel($hNotePadEdit)
; Where is beginning of line?
$iLineStartPos = _GUICtrlEdit_LineIndex($hNotePadEdit, -1)

; Get text of the line
$sLine = _GUICtrlEdit_GetLine($hNotePadEdit, _GUICtrlEdit_LineFromChar($hNotePadEdit, -1))

; Find ends of current word
$iStartPos = StringInStr($sLine, " ", 0, -1, $aCaretPos[0] - $iLineStartPos)
$iEndPos = StringInStr($sLine, " ", 0, 1, $aCaretPos[0] - $iLineStartPos)
If $iEndPos = 0 Then $iEndPos = StringLen($sLine) + 1
; Extract word
$sWord = StringMid($sLine, $iStartPos + 1, $iEndPos - $iStartPos - 1)

; Display word
MsgBox(0, "Found", $sWord)

Ask if anything is unclear.

M23

[Jos]

ok... I stand corrected ...

[funkey]

Another way without GuiEdit.au3

Global $hNotePad = WinGetHandle("[Class:Notepad]")

HotKeySet("{Esc}", "_Exit")
HotKeySet("^g", "_GetWordFromCaret")


While 1
 Sleep(10000)
WEnd

Func _GetWordFromCaret()
 Local $sRet
 Local $iLine = ControlCommand($hNotePad, "", "Edit1", "GetCurrentLine", "")
 Local $iCol = ControlCommand($hNotePad, "", "Edit1", "GetCurrentCol", "")
 Local $sLine = ControlCommand($hNotePad, "", "Edit1", "GetLine", $iLine)
 If StringMid($sLine, $iCol, 1) = " " Then $iCol -= 1
 Local $iFirst = StringInStr($sLine, " ", 0, -1, $iCol)
 $sLine = StringTrimLeft($sLine, $iFirst)
 Local $iLast = StringInStr($sLine, " ", 0, 1)
 If $iLast <> 0 Then
  $sLine = StringLeft($sLine, $iLast - 1)
 EndIf
 ConsoleWrite($sLine & @CR)
EndFunc

Func _Exit()
 Exit
EndFunc