Return The Index Number of A List Control

[FlintBrenick]

I have a one dimensional array that I'm displaying in a list control and I'm trying to create three functions for the list control. I want to be able to move an item up on the list, down on the list, and remove and item from the list (and the array at the same time). Unless there is a functions that I've overlooked, the best way I know to do this to get the index number of which line is selected on the list, process the appropriate function in the array, then set my list to match my array. The only problem is that I don't know how to get the index number so that I know which line on the list is selected. The only thing I can figure out is that I can get the text of the line that is selected and then compare it to each item in the array until I find a match and just hope that the item selected isn't a duplicated further down on this list.

So the root of the question is, how to I get the index number of the line that is selected in a list control? Any other ideas on how I could streamline the process would be greatly appreciated. Thanks guys!

[Melba23]

FlintBrenick,

If you were to consider using a ListView rather than a ListBox, then the code I posted here will do just what you want (and a bit more!).

Or if you insist on a ListBox, you can use this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiListBox.au3>
#include <WinAPI.au3>

$fDblClk = False

Global $sList = "One|Two|Three|Four"

$hGUI = GUICreate("Test", 500, 500)

$hListBox = GUICtrlCreateList("", 10, 10, 200, 200, $LBS_NOTIFY )
$hList_Handle = GUICtrlGetHandle($hListBox)

GUICtrlSetData($hListBox, $sList)

GUISetState()

GUIRegisterMsg($WM_COMMAND, "WM_ListBox_DoubleClick")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    If $fDblClk = True Then
        $fDblClk = False
        $iIndex = _GUICtrlListBox_GetCaretIndex($hListBox)
        ConsoleWrite($iIndex & @CRLF)
    EndIf

WEnd

; React to double clicks on listbox
Func WM_ListBox_DoubleClick($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam
    If BitAND($wParam, 0xFFFF) = $hListBox Then ; LoWOrd = ControlID
        If BitShift($wParam, 16) = 2 Then $fDblClk = True ; HiWord = $LBN_DBLCLK
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>MY_WM_COMMAND

I hope that helps.

M23

Edit. Added a bit more!

Edited June 18, 2010 by Melba23

[Spiider11]

Thanks man that helped me a lot to understand how ListBox works