Jump to content
Sign in to follow this  
miketh2005

_IECreateEmbedded without scrollbars?

Recommended Posts

miketh2005

Hi. This is my code:

#include <IE.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <GuiConstants.au3>

_IEErrorHandlerRegister()

$oIE = _IECreateEmbedded()

Opt("TrayOnEventMode", 1)
Opt("TrayMenuMode", 1)
Opt("GUIOnEventMode", 1)

#region ### START Koda GUI section ### Form=c:\users\mike\documents\chatboxappform.kxf
$chatboxappform = GUICreate("CheatingNetwork Subscriber Chatbox Desktop Application", 578, 385, 199, 258)
GUISetIcon("C:\Users\Mike\Downloads\favicon(2).ico")
GUISetFont(10, 400, 0, "Impact")
$Login = GUICtrlCreateButton("Login", 276, 125, 75, 25, $WS_GROUP)
GUICtrlSetOnEvent(-1, "chatbox")
$usernamelabel = GUICtrlCreateLabel("Username:", 146, 3, 63, 21)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x000000)
$passwordlabel = GUICtrlCreateLabel("Password:", 362, 3, 61, 21)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x000000)
GUICtrlCreateInput("", 146, 22, 121, 25)
GUICtrlCreateInput("", 362, 22, 121, 25)
$madeby = GUICtrlCreateLabel("Made by miketh2005", 2, 0, 117, 21)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x000000)
$Pic1 = GUICtrlCreatePic("C:\Users\Mike\Desktop\cheatingnetworklogo.jpg", 0, 0, 578, 153, BitOR($SS_NOTIFY, $WS_GROUP, $WS_CLIPSIBLINGS))
TraySetClick("16")
$Launch = TrayCreateItem("Launch")
TrayItemSetOnEvent($Launch, "show")
TraySetOnEvent($TRAY_EVENT_PRIMARYDOUBLE, "show")
TraySetIcon("C:\Users\Mike\Downloads\favicon(2).ico", $Launch)
GUISetOnEvent($GUI_EVENT_MINIMIZE, "hide")
GUISetOnEvent($GUI_EVENT_CLOSE, "exxit")
GUISetState(@SW_SHOW)
#endregion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            GUIDelete()
            Exit
    EndSwitch
WEnd

Func chatbox()
    $GUIActiveX = GUICtrlCreateObj($oIE, 0, 153, 0, 232)
    _IENavigate($oIE, "http://www.yahoo.com")
    $oIE.document.body.scroll = "no"
    $oIE.document.body.style.border = "0px"
EndFunc   ;==>chatbox

Func hide()
    GUISetState(@SW_HIDE)
EndFunc   ;==>hide

Func show()
    GUISetState(@SW_SHOW)
EndFunc   ;==>show

Func exxit()
    Exit
EndFunc   ;==>exxit

When you press "Login", the ie window is suppose to imbed, but I don't want scrollbars on the IE window.

$oIE.document.body.scroll = "no"

$oIE.document.body.style.border = "0px"

Isn't working :/

Thanks.

Share this post


Link to post
Share on other sites
PsaltyDS

I'm not sure about disabling the scrollbar completely, but this removes them after each navigation complete event:

#include <IE.au3>
#include <GUIConstantsEx.au3>

_IEErrorHandlerRegister()

Opt("GUIOnEventMode", 1)

Global $hGUI, $idInput_UserName, $idInput_PW, $idButton_Login, $oIE, $idIE

$hGUI = GUICreate("Test", 600, 400)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Quit")
GUICtrlCreateLabel("Username:", 50, 10, 65, 20)
$idInput_UserName = GUICtrlCreateInput("", 125, 8, 125, 25)
GUICtrlCreateLabel("Password:", 270, 10, 65, 20)
$idInput_PW = GUICtrlCreateInput("", 345, 8, 125, 25)
$idButton_Login = GUICtrlCreateButton("Login", 490, 10, 75, 25)
GUICtrlSetOnEvent(-1, "_LoginButton")
$oIE = _IECreateEmbedded()

GUISetState(@SW_SHOW)

While 1
    Sleep(10)
WEnd

Func _LoginButton()
    $idIE = GUICtrlCreateObj($oIE, 10, 50, 580, 340)
    ControlDisable($hGUI, "", $idButton_Login)
    ObjEvent($oIE, "_IEEvent_", "DWebBrowserEvents2")
    _IENavigate($oIE, "http://www.autoitscript.com")
EndFunc   ;==>_LoginButton

Func _IEEvent_NavigateComplete2($ptrBrowser, $ptrURL)
    ConsoleWrite("Debug:  _IEEvent_NavigateComplete2()" & @LF)
    $oIE.document.body.scroll = "no"
EndFunc   ;==>_IEEvent_NavigateComplete2

Func _Quit()
    Exit
EndFunc   ;==>_Quit

:blink:


Valuater's AutoIt 1-2-3, Class... Is now in Session!For those who want somebody to write the script for them: RentACoder"Any technology distinguishable from magic is insufficiently advanced." -- Geek's corollary to Clarke's law

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

×