Detecting traytip

[marselo]

i need to detect if theres a traytip with some text, how can i do that?

[Melba23]

marselo,

This script clicks on a systray icon with the required text, but you can easily modify it to do what you want:

expandcollapse popup

#Include <GuiToolBar.au3>

Global $hSysTray_Handle, $iSystray_ButtonNumber

Global $sToolTipTitle = "" ; <<<<<<<<<<<<<<<< Enter some tooltip text for the icon you want here

$iSystray_ButtonNumber = Get_Systray_Index($sToolTipTitle)

If $iSystray_ButtonNumber = 0 Then
    MsgBox(16, "Error", "Icon not found in system tray")
    Exit
Else
    Sleep(500)
    _GUICtrlToolbar_ClickButton($hSysTray_Handle, $iSystray_ButtonNumber, "right")
EndIf

Exit

;............

Func Get_Systray_Index($sToolTipTitle)

    ; Find systray handle
    $hSysTray_Handle = ControlGetHandle('[Class:Shell_TrayWnd]', '', '[Class:ToolbarWindow32;Instance:1]')
    If @error Then
        MsgBox(16, "Error", "System tray not found")
        Exit
    EndIf

    ; Get systray item count
    Local $iSystray_ButCount = _GUICtrlToolbar_ButtonCount($hSysTray_Handle)
    If $iSystray_ButCount = 0 Then
        MsgBox(16, "Error", "No items found in system tray")
        Exit
    EndIf

    ; Look for wanted tooltip
    For $iSystray_ButtonNumber = 0 To $iSystray_ButCount - 1
        If StringInStr(_GUICtrlToolbar_GetButtonText($hSysTray_Handle, $iSystray_ButtonNumber), $sToolTipTitle) <> 0 Then ExitLoop
    Next

    If $iSystray_ButtonNumber = $iSystray_ButCount Then
        Return 0 ; Not found
    Else
        Return $iSystray_ButtonNumber ; Found
    EndIf

EndFunc

I hope it helps.

M23

[marselo]

thanks =) it helped in some way. but what i need is the bubble pop up in the tray area.

i tried using window info in AU tools, it detects it as a window. but i tried the "WinExists" command and it didnt work :/

[Melba23]

marselo,

but what i need is the bubble pop up in the tray area

Like I said - it is easy to adjust this code. Replace the top part of the code I posted by this:

#Include <GuiToolBar.au3>

HotKeySet("{ESC}", "On_Exit")  ; Just so you can exit from this demo

Global $hSysTray_Handle, $iSystray_ButtonNumber

Global $sToolTipTitle = "" ; <<<<<<<<<<<<<<<< Enter some tooltip text for the icon you want here

$iSystray_ButtonNumber = Get_Systray_Index($sToolTipTitle)

If $iSystray_ButtonNumber = 0 Then
    $sMsg = "Not Found"
Else
    $sMsg = "Found!"
EndIf
TrayTip ($sToolTipTitle, $sMsg, 30)

While 1
    Sleep(10) ; Just so the traytip has time to appear
WEnd

Func On_Exit()
    Exit
EndFunc

Try and code somethign by yourself next time - it makes for a more satisfying coding experience!

M23