Using Random and small question about mail

[Dubler]

Hi!

I have problem with my program:

i have

$1, $2, $3, $4, $5 and $6

I want in order to they were not repeated. I using that:

$1 = Random(1, 49, 1)
$2 = Random(1, 49, 1)
$3 = Random(1, 49, 1)
$4 = Random(1, 49, 1)
$5 = Random(1, 49, 1)
$6 = Random(1, 49, 1)

And second question:

how to do automatic mail sender for yahoo?

Edited July 19, 2010 by Dubler

[Melba23]

Dubler,

Welcome to the AutoIt forum.

Here is one way to get 6 unique random numbers between 1-49 inclusive - which is what I believe you asked.

#include <Array.au3>

Global $aArray[6], $1, $2, $3, $4, $5, $6

; For each element of the array
For $i = 0 To 5

    ; Start a loop
    While 1
        ; Get a random number in the range
        $iTemp = Random(1, 49, 1)
        ; Clear error flag
        $fError = 0
        ; Check if the value is already in the array
        For $j = 0 To $i - 1
            ; if it is, set the flag
            If $aArray[$j] = $iTemp Then $fError = 1
        Next
        ; If the flag is not set
        If $fError = 0 Then
            ; Store the value in the array for later checking
            $aArray[$i] = $iTemp
            ; Assign the value to the variable
            Assign($i + 1, $iTemp)
            ; Leave the loop and move on to the next element
            ExitLoop
        EndIf
    ; If the flag was set, get another random value and search again
    WEnd

Next

; Display the results
MsgBox(0, "Result", "$1 = " & $1 & @CRLF &  "$2 = " & $2 & @CRLF & "$3 = " & $3 & @CRLF & "$4 = " & $4 & @CRLF & "$5 = " & $5 & @CRLF & "$6 = " & $6)

To learn about sending mail - use the Search box at top right. You will find many topics about it like this one.

M23