How to make title and text right-justified in inputbox?

[omeron]

Hi everybody,

I'm a real beginner so forgive me if my question is stupid....

In MsgBox there is flag value 524288 to make title and text right-justified. How do I do it in inputbox?

Thanks

[Melba23]

omeron,

Welcome to the AutoIt forum.

How do I do it in inputbox

I do not believe you can as there is no way to set the styles for an InputBox.

You will have to write your own GUI like this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <EditConstants.au3>

$vInput = _Get_Input()

MsgBox(0, "Input", $vInput)

Func _Get_Input()

    $hGUI = GUICreate("Get Input", 180, 100, Default, Default, BitOR($WS_CAPTION, $WS_POPUP, $WS_SYSMENU), $WS_EX_TOPMOST)

    GUICtrlCreateLabel("Please type the input!", 10, 10, 160, 20, $SS_RIGHT)

    $hInput = GUICtrlCreateInput("", 10, 40, 160, 20, $ES_RIGHT)

    $hOK_Button = GUICtrlCreateButton("OK", 10, 70, 75, 20)
    $hCan_Button = GUICtrlCreateButton("Cancel", 95, 70, 75, 20)

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $hCan_Button
                Exit
            Case $hOK_Button
                $vInput = GUICtrlRead($hInput)
                GUIDelete($hGUI)
                Return $vInput
        EndSwitch
    WEnd
    
EndFunc

M23

Edit: Added welcome!

Edited July 28, 2010 by Melba23