Sending Text to GUI

[riceking]

$i = 0
    $Random = Random(25, 200, 1)

    Do
        Send($i)
        $i = $i + 1
        $LoopsLeft = $Random - $i
    Until $i = $Random

I wish to project the value of $LoopsLeft onto the GUI that I will make. What would I project it to, an input, a label? Any help appreciated.

Edit:

Could I

$Input1 = GUICtrlCreateInput("N", 86, 30, 53, 21, $GUI_SS_DEFAULT_INPUT)

do this?

$Input1 = GUICtrlCreateInput($LoopLeft, 86, 30, 53, 21, $GUI_SS_DEFAULT_INPUT)

Edited August 4, 2010 by riceking

[notsure]

Whats wrong with;

GUICtrlSetData ( $input1, $Loopleft )

?

[Melba23]

riceking,

Does this help?

expandcollapse popup

#include <GUIConstantsEx.au3>

; Create GUI
$hGUI = GUICreate("Test", 500, 500)

; Create label to display count
$hLabel = GUICtrlCreateLabel("", 10, 10, 50, 50)
GUICtrlSetFont(-1, 18)

; Show GUI
GUISetState()

; Determine number of loops
$iLoopsLeft = Random(25, 200, 1)
; Start timer
$iBegin = TimerInit()

While 1

    ; See if [X] is pressed
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Have the loops finished?
    If $iLoopsLeft > 0 Then
        ; Has the timer run for i/2 sec
        If TimerDiff($iBegin) > 500 Then ; Adjust the timer value to suit
            ; Reduce number of loops left
            $iLoopsLeft -= 1
            ; Display result
            GUICtrlSetData($hLabel, $iLoopsLeft)
            ; Reset timer
            $iBegin = TimerInit()
        EndIf
    EndIf

WEnd

M23