Sign in to follow this  
Followers 0
agivx3

Identify multiple treeviews

2 posts in this topic

#1 ·  Posted (edited)

Hi all !!

i am using a gui which contains 2 treeviews. How can i identify the treeview handle or controlID (or the treeview item) when i am clicking on a treeview item.

With only one treeview everything works fine. I used for example the GUICtrlRead($treeview1,1) to read the item text clicked on. But with 2 treeviews i dont know from which of both an item is selected.

I also tried $msg = GuiGetMsg(1) and then $msg[2] to get the needed information. But this dont seems to work ?!?

Maybe anyone has a solution or idea for this...

Thanks

Andi

Edited by agivx3

Share this post


Link to post
Share on other sites



agivx3,

Welcome to the AutoIt forum. ;)

You need to intercept the click message and see which control issued it - like this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>

; Set a flag to show which TreeView was clicked
Global $fTV = 0

$hGUI = GUICreate("Test", 500, 500)

$hTV_1 = GUICtrlCreateTreeView(10, 10, 200, 200)
$hWndTV_1 = GUICtrlGetHandle(-1)
For $i = 1 To 5
    GUICtrlCreateTreeViewItem("Item 1" & $i, $hTV_1)
Next

$hTV_2 = GUICtrlCreateTreeView(260, 10, 200, 200)
$hWndTV_2 = GUICtrlGetHandle(-1)
For $i = 1 To 5
    GUICtrlCreateTreeViewItem("Item 2" & $i, $hTV_2)
Next

GUISetState()

; Intercept click messages
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Is the flag set?
    If $fTV <> 0 Then
        ; Announce it
        MsgBox(0, "Click!", "You clicked in TreeView " & $fTV)
        ; Clear flag
        $fTV = 0
    EndIf

WEnd

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndTreeview

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    ; Has a click occured?
    Switch $iCode
        Case $NM_CLICK
            ; Which TreeView
            Switch $hWndFrom
                Case $hWndTV_1
                    ; It was TV_1
                    $fTV = 1
                Case $hWndTV_2
                    ; It was TV_2
                    $fTV = 2
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

If you are not too sure about using GUIRegisterMsg, could I recommend this tutorial in the Wiki? ;)

Please ask if you have any questions. :)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0