file/folder properties from deleted item?

[hot202 0]

Hey is there anyway to get the file properties from a file or folder that has been deleted?

Or is there anyway to get the file path to the recycle bin directory?

[wakillon 391]

Hey is there anyway to get the file properties from a file or folder that has been deleted?

Or is there anyway to get the file path to the recycle bin directory?

Can't access to file properties if deleted

C:\RECYCLER, D:\RECYCLER, E:\RECYCLER

[hot202 0]

damn thanks anyway

[Melba23 2,491]

wakillon,

You give in too easily!

hot202,

Try this:

; Credit to Prog@ndy

$objRecycleBin = _GetRecycleBin()

If IsObj($objRecycleBin) Then

    ; Get Special Folder based upon input name
    $objFolderItems = $objRecycleBin.Items() ; Get items within Recycle Bin

    For $objItem In $objFolderItems
        If ($objItem.Type = "File Folder") Then
            ConsoleWrite("FOLDER:" & @CRLF)
        Else
            ConsoleWrite("FILE:" & @CRLF)
        EndIf
        ConsoleWrite("ORIGINAL FILENAME: " & $objRecycleBin.GetDetailsOf($objItem, 0) & @CRLF)
        ConsoleWrite("ORIGINAL PATH: " & $objRecycleBin.GetDetailsOf($objItem, 1) & @CRLF)
        ConsoleWrite("DELETED DATE: " & $objRecycleBin.GetDetailsOf($objItem, 2) & @CRLF)
        ConsoleWrite("FILESIZE: " & $objRecycleBin.GetDetailsOf($objItem, 3) & @CRLF)
        ConsoleWrite("FILETYPE DESCRIPTION: " & $objRecycleBin.GetDetailsOf($objItem, 4) & @CRLF)
        ConsoleWrite("DATE CREATED: " & $objRecycleBin.GetDetailsOf($objItem, 5) & @CRLF)
        ConsoleWrite("DATE ACCESSED: " & $objRecycleBin.GetDetailsOf($objItem, 6) & @CRLF)
        ConsoleWrite("DATE MODIFIED: " & $objRecycleBin.GetDetailsOf($objItem, 7) & @CRLF)
        ConsoleWrite("FILE ATTRIBUTES: " & $objRecycleBin.GetDetailsOf($objItem, 8) & @CRLF & @CRLF)
    Next
Else
    MsgBox(0, "", "Could not find Recycle Bin")
EndIf

Func _GetRecycleBin()
    Local $objShellApp = ObjCreate("Shell.Application")
    Local $ssfBITBUCKET = 10
    Return $objShellApp.NameSpace($ssfBITBUCKET)
EndFunc   ;==>_GetRecycleBin

Enjoy!

M23

[wakillon 391]

Joli !

But the question was "get the file properties from a file or folder that has been deleted"

They are not deleted in RecycleBin !

And i does'nt see the RecycleBin path in your answer !

Et toc ...

Edited September 3, 2010 by wakillon

[hot202 0]

i found this with google but i dont really understand it but dose it mean you can get the properties?

Const RECYCLE_BIN = &hA&

Dim objShell: Set objShell = _
CreateObject("Shell.Application")
Dim objShellFolder: Set objShellFolder = _
objShell.Namespace(RECYCLE_BIN)

Dim arrHeaders(33), i
'Get the descriptions of available info
For i = 0 to 33
arrHeaders(i) = i & vbTab & _
objShellFolder.GetDetailsOf(objShellFolder.Items, i)
Next
'MsgBox Join(arrHeaders, vbCrLf)

Dim strFileName, iResponse
For Each strFileName in objShellFolder.Items
sMsg = ""
'Get the info associated with each description
For i = 0 to 33
sMsg = sMsg & arrHeaders(i) & _
Next

iResponse = MsgBox(sMsg, 1)
If iResponse = 2 Then WScript.Quit
Next

[Melba23 2,491]

wakillon,

They are not deleted in RecycleBin

OK - 15 partout!

M23

[hot202 0]

this cant be changed to work?

Const $RECYCLE_BIN = 10
Const $FILE_SIZE = 5

Local $objShell = ObjCreate("Shell.Application")
If IsObj ($objShell) Then

Else
    MsgBox (0, "ERROR", "Shell.Application is not an object.")
EndIf
Local $objFolder = $objShell.Namespace($RECYCLE_BIN)

Local $colItems = $objFolder.Items
Local $strSize, $intSize

For $objItem in $colItems
    $strSize = $objFolder.GetDetailsOf($objItem, $FILE_SIZE)
    $arrSize = StringTrimRight($strSize, 3)
    $intSize = $intSize + $arrSize
    MsgBox(1,"test", $intSize)

Next

ConsoleWrite( $intSize & " KB")

[Melba23 2,491]

hot202,

this cant be changed to work?

Of course it can!

Const $RECYCLE_BIN = 10
Const $FILE_SIZE = 3

Local $objShell = ObjCreate("Shell.Application")
If Not IsObj($objShell) Then
    MsgBox (0, "ERROR", "Shell.Application is not an object.")
    Exit
EndIf

Local $objFolder = $objShell.Namespace($RECYCLE_BIN)

Local $colItems = $objFolder.Items
Local $strSize, $intSize

For $objItem in $colItems
    $strName = $objFolder.GetDetailsOf($objItem, 0)
    $strSize = $objFolder.GetDetailsOf($objItem, $FILE_SIZE)
    ConsoleWrite($strName & " = " & $strSize & @CRLF)
Next

M23

[wakillon 391]

Melba23

I prefer your first solution, there is more informations

[hot202 0]

so if i want to get the full properties of a file like the song title and stuff, im best to check if its in the recycle bin still and if it is move it out then get the properties then delete the item again? or would there be a better way to do this?

[Melba23 2,491]

hot202,

As far as I know, the only properties you can retrieve from files in the ReCycle bin are those in my earlier post. If you want the more advanced ones, I think you will have to undelete the file first.

M23