GUICtrlCreateEdit problem

[ASut]

I find that "Ctrl + A" can't work in the GUICtrlCreateEdit, every time when I need to copy all the text inside the GUICtrlCreateEdit, I need to right clik the mouse and then select "Select All",How to make Ctrl + A work in the GUICtrlCreateEdit?

[NicePerson]

Try this

Send("^{A}")

[Melba23]

ASut,

This will work if you do not keep the A key pressed long enough to start the typematic repeat:

#include <GUIConstantsEx.au3>
#include <GUIEdit.au3>
#include <WinAPI.au3>

Global $hInput_Handle

HotKeySet("^a", "_SelAll")

$hGUI = GUICreate("Test", 500, 500)

$hInput = GUICtrlCreateEdit("here is some text", 10, 10, 480, 480)
$hInput_Handle = GUICtrlGetHandle(-1)

$hSelAll = GUICtrlCreateDummy()

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func _SelAll()

    Switch _WinAPI_GetFocus()
        Case $hInput_Handle
            _GUICtrlEdit_SetSel($hInput_Handle, 0, -1)
            Return
    EndSwitch

EndFunc   ;==>_SelAll

M23

[ASut]

Thanks, I have tried all 2 methods, for Send("^{A}") I don't know how to make it works, for M23 's method, How can it work for 2 or more GUICtrlCreateEdit?

[Kalin]

Thanks, I have tried all 2 methods, for Send("^{A}") I don't know how to make it works, for M23 's method, How can it work for 2 or more GUICtrlCreateEdit?

Ctrl+C

Or try this function I made a while ago.

INPUTBOX("Copy All","Edit Strings Below"&@CRLF&@CRLF&"Note: Ctrl+C = Copy",GUICTRLREAD($YourEditControlVarName))

Edited September 19, 2010 by Kalin

[Melba23]

ASut,

for M23 's method, How can it work for 2 or more GUICtrlCreateEdit?

Just test for the different handles - like this:

#include <GUIConstantsEx.au3>
#include <GUIEdit.au3>
#include <WinAPI.au3>

Global $hInput_Handle

HotKeySet("^a", "_SelAll")

$hGUI = GUICreate("Test", 500, 500)

$hInput_1 = GUICtrlCreateEdit("here is some text", 10, 10, 230, 480)
$hInput_1_Handle = GUICtrlGetHandle(-1)
$hInput_2 = GUICtrlCreateEdit("here is some text", 260, 10, 230, 480)
$hInput_2_Handle = GUICtrlGetHandle(-1)

$hSelAll = GUICtrlCreateDummy()

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func _SelAll()

    Switch _WinAPI_GetFocus()
        Case $hInput_1_Handle
            _GUICtrlEdit_SetSel($hInput_1_Handle, 0, -1)
        Case $hInput_2_Handle
            _GUICtrlEdit_SetSel($hInput_2_Handle, 0, -1)
    EndSwitch

EndFunc   ;==>_SelAll

[ASut]

Thanks again for the help,which really help me a lot

[Melba23]

ASut,

That is why I am here. Glad I could help.

M23

[Kalin]

ASut,

That is why I am here. Glad I could help.

M23

He was thanking me, stfuuuuuuuuuuuu.

Joking, but srsly.

;-;

[Melba23]

Kalin,

Try increasing the medication - or stopping it altogether if you prefer.

M23

[GEOSoft]

ASut,

That is why I am here. Glad I could help.

M23

I'm certainly glad you answered that question.

Oooops, I quoted the reply and I'm sooooooooo sorry (NOT). I can show you boards where you would get fried for not quoting at least part of the post you are replying to.

Yes big M, I'm in an ugly mood and it was that lucky day where your name came out of the hat.

[Melba23]

George,

Perhaps you need a new dosage (or is that dotage? ) prescription as well!

M23

[Kalin]

Kalin,

Try increasing the medication - or stopping it altogether if you prefer.

M23

Don't try flamming me Melba.

I said it was a joke.

[Melba23]

Kalin,

If you cannot take banter - then do not start it.

"click"

M23

[Mat]

Kalin,

If you cannot take banter - then do not start it.

"click"

M23

The "click" lacks the same effect as when Jos uses it... Maybe it's the fact it no longer has the big red

[Melba23]

Mat,

CLICK!!!!!

Better?

M23

[Mat]

Mat,

CLICK!!!!!

Better?

M23

No... I like the posts like this: #823687

Final and no nonsense. It gives the impression that the *click* is not open to any discussion.

[ASut]

By using M23's method, I can use "Ctrl +A" to select all the text in GUICtrlCreateEdit , but I got new question, it seems that I can't use "Ctrl +A" in other applications, e.g Notepad, and even SciTE.

[Melba23]

ASut,

If we use an accelerator instead of a HotKey, we can get over that problem:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GUIEdit.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 500, 500)

$hInput_1 = GUICtrlCreateEdit("here is some text", 10, 10, 230, 480)
$hInput_1_Handle = GUICtrlGetHandle(-1)
$hInput_2 = GUICtrlCreateEdit("here is some text", 260, 10, 230, 480)
$hInput_2_Handle = GUICtrlGetHandle(-1)

$hSelAll = GUICtrlCreateDummy()

GUISetState()
; Set accelerator for Ctrl+a
Global $aAccelKeys[1][2]=[["^a", $hSelAll]]
GUISetAccelerators($aAccelKeys)

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hSelAll
            _SelAll()
    EndSwitch

WEnd

Func _SelAll()

    Switch _WinAPI_GetFocus()
        Case $hInput_1_Handle
            _GUICtrlEdit_SetSel($hInput_1_Handle, 0, -1)
        Case $hInput_2_Handle
            _GUICtrlEdit_SetSel($hInput_2_Handle, 0, -1)
    EndSwitch

EndFunc   ;==>_SelAll

Better?

M23

[ASut]

yeah, it is much better, and work fine for me, thanks sooooooooooooooooooooooooo much