Sign in to follow this  
Followers 0
Mohit

Need Help With the Guictrlcreate Tab

3 posts in this topic

Guys , i Have created the tabs i was just wondering is it possible that say i have 5 tabs each tab can have a different background Image Or Color.

Share this post


Link to post
Share on other sites



#2 ·  Posted (edited)

Mohit,

You can colour the tabs lke this: ;)

#include <GuiConstantsEx.au3>
#include <GuiTab.au3>

$hGUI = GUICreate("_GUICtrlTab_SetBkColor() Demo", 320, 280)

$hTab = GUICtrlCreateTab(10, 20, 300, 250)

GUICtrlCreateTabItem("Tab 1")
_GUICtrlTab_SetBkColor($hGUI, $hTab, 0xFF0000)

GUICtrlCreateButton("Some Button", 20, 50)

GUICtrlCreateTabItem("Tab 2")
_GUICtrlTab_SetBkColor($hGUI, $hTab, 0x00CC00)

GUICtrlCreateCheckbox("Some Checkbox", 20, 50)

 GUICtrlCreateTabItem(""); end tabitem definition

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _GUICtrlTab_SetBkColor($hWnd, $hSysTab32, $sBkColor)

    Local $aTabPos = ControlGetPos($hWnd, "", $hSysTab32)
    Local $aTab_Rect = _GUICtrlTab_GetItemRect($hSysTab32, -1)
    GUICtrlCreateLabel("", $aTabPos[0] + 2, $aTabPos[1] + $aTab_Rect[3] + 4, $aTabPos[2] - 6, $aTabPos[3] - $aTab_Rect[3] - 7)
    GUICtrlSetBkColor(-1, $sBkColor)
    GUICtrlSetState(-1, $GUI_DISABLE)

EndFunc   ;==>_GUICtrlTab_SetBkColor

I have never tried images. Give it a go using the same principle and see if it works - please let me know how you get on. :)

M23

Edit: I got bored (Ryder Cup rained off) - it does work for images as well:

Func _GUICtrlTab_SetBkPic($hWnd, $hSysTab32, $sPic)

    Local $aTabPos = ControlGetPos($hWnd, "", $hSysTab32)
    Local $aTab_Rect = _GUICtrlTab_GetItemRect($hSysTab32, -1)
    GUICtrlCreatePic($sPic, $aTabPos[0] + 2, $aTabPos[1] + $aTab_Rect[3] + 4, $aTabPos[2] - 6, $aTabPos[3] - $aTab_Rect[3] - 7)
    GUICtrlSetState(-1, $GUI_DISABLE)

EndFunc   ;==>_GUICtrlTab_SetBkPic
Edited by Melba23

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

thanks i will try that.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0