List view column does not stay hidden

[Der_Andi 0]

Hi all,

I've got a listview with three columns. The first two columns have a width of 0, so they are hidden. But when I add new items, the second column gets visible. The first column stays hidden.

How can I prevent the second column from getting visible? Just setting it to 0 again seems to be not right for me.

Here's an example, demonstrating the problem:

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

GUICreate("", 400, 300)
$hListView = GUICtrlCreateListView("||items", 2, 2, 394, 268)

_GUICtrlListView_SetColumnWidth($hListView, 0, 0)
_GUICtrlListView_SetColumnWidth($hListView, 1, 0)

GUICtrlCreateListViewItem("hidden|hidden|visible", $hListView)
GUICtrlCreateListViewItem("hidden|hidden|visible", $hListView)
GUICtrlCreateListViewItem("hidden|hidden|visible", $hListView)

GUISetState()
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

[Der_Andi 0]

Not sure if this is what you looking for :

;...
GUICtrlCreateListViewItem("||visible", $hListView)
GUICtrlCreateListViewItem("||visible", $hListView)
GUICtrlCreateListViewItem("||visible", $hListView)
;...

Eh... is this a joke? :-P

Seriously, why would I create two hidden columns and leave them empty?

Edited October 11, 2010 by Der_Andi

[Melba23 2,858]

Der_Andi,

I am afraid I have not come up with anything better than rehiding the column each time you add an item.

Why do you want to have the first 2 columns hidden? Perhaps there is another way to do this.

M23

[PsaltyDS 30]

Don't mix the native AutoIt GUI functions with the UDF functions if you can help it. It works fine if you use the UDF throughout:

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

$hGUI = GUICreate("", 400, 300)
$hListView = _GUICtrlListView_Create($hGUI, "hidden|hidden|visible", 10, 10, 380, 280)

_GUICtrlListView_SetColumnWidth($hListView, 0, 0)
_GUICtrlListView_SetColumnWidth($hListView, 1, 0)

For $n = 0 To 3
    _GUICtrlListView_AddItem($hListView, $n & "-0 hidden")
    _GUICtrlListView_AddSubItem($hListView, $n, $n & "-1 hidden", 1)
    _GUICtrlListView_AddSubItem($hListView, $n, $n & "-2 visible", 2)
Next

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

[Der_Andi 0]

Interesting!

I didn't know that mixing native functions with UDF's can have such negative effects. I've been doing this ever since and everything worked out so far.

Thanks for the tip, PSalty.

@Melba:

I hope, it is okay with you, if I just use this solution. It would have been quite a story just to cover the basics of my program ;-)

[Melba23 2,858]

Der_Andi,

Of course!

I was just looking for an alternative solution, but our resident waterfowl has come up with one for us.

M23

[Der_Andi 0]

I'd like to add, that there is indeed a way, how you can mix native GUI functions with UDF's. When using UDF's, make sure you use the handle of the control. Then it works, too. Or in my case: column widths do not change.

Creating listviews with _GUICtrlListView_Create() has one drawback: they are not affected by GUISetFont.

So I found the clue in this thread: http://www.autoitscript.com/forum/index.php?showtopic=70077&view=findpost&p=513807

Edited October 11, 2010 by Der_Andi