Gui window can not be closed ?

[Ericlee]

all the function of this script is ok except the GUI window. it can not be closed when click the close bottom, and i don't know what's the problem?

the code is

#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

HotKeySet('#a','Example')

While 1

Sleep(100)

WEnd

Func Example()

Local $Button_1, $Button_2, $msg

GUICreate("My GUI Button")

Opt("GUICoordMode", 2)

$Button_1 = GUICtrlCreateButton("Button 1", 10, 30, 100)

$Button_2 = GUICtrlCreateButton("Button 2", 0, -1)

GUISetState()

While 1

$msg = GUIGetMsg()

Select

Case $msg = $GUI_EVENT_CLOSE

ExitLoop

Case $msg = $Button_1

MsgBox(0, 'Testing', 'Button 1 was pressed')

Case $msg = $Button_2

MsgBox(0, 'Testing', 'Button 2 was pressed')

EndSelect

WEnd

EndFunc

Edited November 2, 2010 by Ericlee

[BrewManNH]

You code doesn't have anything in it that closes the GUI, exiting the loop just jumps out of the loop, and then goes back to the While...Wend loop waiting for you to hit the Win + a keys again, leaving the window open. If you want the GUI_EVENT_CLOSE to exit the program you need to change the ExitLoop command to Exit. If you want to close the GUI and have the program wait until you hit the Win + a key again, running in the background the whole time, you should put the command GUIDelete() before the ExitLoop.

This example leaves the program running in the background until you hit Win + a again, but kills the GUI:

Func Example()
    Local $Button_1, $Button_2, $msg
    GUICreate("My GUI Button")
    Opt("GUICoordMode", 2)
    $Button_1 = GUICtrlCreateButton("Button 1", 10, 30, 100)
    $Button_2 = GUICtrlCreateButton("Button 2", 0, -1)
    GUISetState()
    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                GUIDelete() ; <<<<<<<<<<<<<<<<< Add this line
                ExitLoop
            Case $msg = $Button_1
                MsgBox(0, 'Testing', 'Button 1 was pressed')
            Case $msg = $Button_2
                MsgBox(0, 'Testing', 'Button 2 was pressed')
        EndSelect
    WEnd
EndFunc

This example will close the program when you close the GUI:

Func Example()
    Local $Button_1, $Button_2, $msg
    GUICreate("My GUI Button")
    Opt("GUICoordMode", 2)
    $Button_1 = GUICtrlCreateButton("Button 1", 10, 30, 100)
    $Button_2 = GUICtrlCreateButton("Button 2", 0, -1)
    GUISetState()
    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                Exit ; <<<<<<<<<<<<<<<<<<<< Change this line
            Case $msg = $Button_1
                MsgBox(0, 'Testing', 'Button 1 was pressed')
            Case $msg = $Button_2
                MsgBox(0, 'Testing', 'Button 2 was pressed')
        EndSelect
    WEnd
EndFunc

[Ericlee]

Thank you Spammer! According to ur advise, My problem has been solved by adding GUIDelete() in my script.