within an edit control - how to enable ctrl+a to select all

[gcue 8]

i couldnt identify which styles/extended styles does this.. or is there another way?

[Necromorph 1]

SetHotKey("^a", "_Func")

Func _Func()
     GUICtrlSetState($hCtrl, $GUI_FOCUS)
EndFunc

not sure if you can actually set the "ctrl" key though, because it is a modifier alrady, but it may work. else you maybe its ("{LCTLR} + a") not sure.

[Melba23 2,460]

gcue,

As you have discovered, Ctrl-A does not "select all" within an edit control, but you can cheat like this:

#include <GUIConstantsEx.au3>
#include <GUIEdit.au3>
#include <WinAPI.au3>

Global $hInput_Handle

$hGUI = GUICreate("Test", 500, 500)

$hInput = GUICtrlCreateEdit("here is some text", 10, 10, 480, 480)
$hInput_Handle = GUICtrlGetHandle(-1)

; Create dummy for accelerator key to activate
$hSelAll = GUICtrlCreateDummy()

GUISetState()

; Set accelerators for Ctrl+a
Dim $AccelKeys[1][2]=[["^a", $hSelAll]]
GUISetAccelerators($AccelKeys)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hSelAll
            _SelAll()
    EndSwitch
WEnd

Func _SelAll()
    Switch _WinAPI_GetFocus()
        Case $hInput_Handle
            _GUICtrlEdit_SetSel($hInput_Handle, 0, -1)
            Return
    EndSwitch
EndFunc   ;==>_SelAll

Ask if it is not clear how the script works.

M23

[gcue 8]

awesome - as always melba... thank you very much!!!

looks straight forward - thought there was a style or something tho.. but this works!!!!

thanks again!