Sign in to follow this  
Followers 0
binarydigit0101

set a window: popup, transparent and moveable!

11 posts in this topic

hi all!

can anyone help me to set window style?

i'd like a window with $WS_POPUP, $WS_EX_TRANSPARENT and moveable.

how can i do this?

thank you so much to all! :-)


ehi ehi ehi, what is your name?

Share this post


Link to post
Share on other sites



#2 ·  Posted (edited)

Can't tell what you tried. Should just be a matter of setting those style in GuiCreate() (see help file), or GuiSetStyle(). If it's not an autoIt GUI, then maybe you'll be into _WinAPI_SetWindowLong().

Post a short demo script of what you tried and say which part doesn't work; you'll get lots of help.

:(

Edit: ...or Melba will just hand out fish and destroy the market for fishing tackle. :graduated:

Edited by PsaltyDS

Valuater's AutoIt 1-2-3, Class... Is now in Session!For those who want somebody to write the script for them: RentACoder"Any technology distinguishable from magic is insufficiently advanced." -- Geek's corollary to Clarke's law

Share this post


Link to post
Share on other sites

binarydigit0101,

Will this do? :graduated:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WINAPI.au3>
#include <sendmessage.au3>

HotKeySet("ESC", "_Exit")

$hGUI = GUICreate("Test", 500, 500, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
GUISetBkColor(0xABCDEF)

GUICtrlCreateLabel("Click on the text to drag this transparent GUI" & @CRLF & "Press ESC to exit", 10, 10)

_WinAPI_SetLayeredWindowAttributes($hGUI, 0xABCDEF, 250)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($hGUI, $WM_SYSCOMMAND, 0xF012, 0)
    EndSwitch
WEnd

Func _Exit()
    Exit
EndFunc

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Can't tell what you tried.

Post a short demo script of what you tried and say which part doesn't work; you'll get lots of help.

:graduated:

ok i ask "excuse me"...

... so i'd like to use:

#include <GUIConstants.au3>
#include <WindowsConstants.au3>

$gui = GUICreate("Informazioni su -aggiorna il mio mys-", 522, 218, 192, 124, *here my question?*)
$id=GUICtrlCreateLabel("agg my mys",50,25,200,100)
GUICtrlSetfont($id,20)
GUICtrlSetcolor($id,0x4169E1)
GUICtrlCreateLabel("versione:       2,3,0",55,75,200,100)
GUICtrlCreateLabel("creato da:     MONITOR YOUR STOCKS                        @company                                                 (SERVERMANIA)",55,100,200,100)
$press=GUICtrlCreateButton("Visualizzazione completata!",350,160,150,35)
GUISetState(@SW_SHOW)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_MINIMIZE
    GUISetState(@SW_RESTORE)
Case $press
    Exit
EndSwitch
WEnd

ehi ehi ehi, what is your name?

Share this post


Link to post
Share on other sites

binarydigit0101,

Will this do? :graduated:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WINAPI.au3>
#include <sendmessage.au3>

HotKeySet("ESC", "_Exit")

$hGUI = GUICreate("Test", 500, 500, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
GUISetBkColor(0xABCDEF)

GUICtrlCreateLabel("Click on the text to drag this transparent GUI" & @CRLF & "Press ESC to exit", 10, 10)

_WinAPI_SetLayeredWindowAttributes($hGUI, 0xABCDEF, 250)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($hGUI, $WM_SYSCOMMAND, 0xF012, 0)
    EndSwitch
WEnd

Func _Exit()
    Exit
EndFunc

M23

wow! nice code!

this can help me but how can i apply $WS_POPUP as background?

t.y.! ;-)


ehi ehi ehi, what is your name?

Share this post


Link to post
Share on other sites

okay, maybe my question is so impossible...

sometimes i'm going crazy! :graduated:


ehi ehi ehi, what is your name?

Share this post


Link to post
Share on other sites

binarydigit0101,

how can i apply $WS_POPUP as background?

I do not understand what you mean. $WS_POPUP is a style used to create a GUI without borders or title bar - it has nothing to do with the background. :graduated:

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Try this:

#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <SendMessage.au3>

Global Const $SC_DRAGMOVE = 0xF012
$gui = GUICreate("Informazioni su -aggiorna il mio mys-", 522, 218, 192, 124, $WS_POPUP, $WS_EX_LAYERED)
GUISetBkColor(0x01, $gui)
$id=GUICtrlCreateLabel("agg my mys",50,25,200,100)
GUICtrlSetfont($id,20)
GUICtrlSetcolor($id,0x4169E1)
GUICtrlCreateLabel("versione:       2,3,0",55,75,200,100)
GUICtrlCreateLabel("creato da:  MONITOR YOUR STOCKS                     @company                                                (SERVERMANIA)",55,100,200,100)
$press=GUICtrlCreateButton("Visualizzazione completata!",350,160,150,35)
_WinAPI_SetLayeredWindowAttributes($gui, 0x01, 255)
GUISetState(@SW_SHOW)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_MINIMIZE
    GUISetState(@SW_RESTORE)
Case $press
    Exit
Case $GUI_EVENT_PRIMARYDOWN
_SendMessage($gui, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
EndSwitch
WEnd

Br,

UEZ


Please don't send me any personal message and ask for support! I will not reply!

Selection of finest graphical examples at Codepen.io

The own fart smells best!
Her 'sikim hıyar' diyene bir avuç tuz alıp koşma!
¯\_(ツ)_/¯  ٩(●̮̮̃•̃)۶ ٩(-̮̮̃-̃)۶ૐ

Share this post


Link to post
Share on other sites

#9 ·  Posted (edited)

Here's another way of doing it:

#include <GUIConstants.au3>
#include <WindowsConstants.au3>
GUIRegisterMsg($WM_NCHITTEST, "_MY_NCHITTEST")
$gui = GUICreate("Informazioni su -aggiorna il mio mys-", 522, 218, 192, 124, $WS_POPUP)
$id=GUICtrlCreateLabel("agg my mys",50,25,200,100)
GUICtrlSetfont($id,20)
GUICtrlSetcolor($id,0x4169E1)
GUICtrlCreateLabel("versione:       2,3,0",55,75,200,100)
GUICtrlCreateLabel("creato da:     MONITOR YOUR STOCKS                        @company                                                 (SERVERMANIA)",55,100,200,100)
$press=GUICtrlCreateButton("Visualizzazione completata!",350,160,150,35)
GUISetState(@SW_SHOW)
WinSetTrans("Informazioni", "", 150)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_MINIMIZE
    GUISetState(@SW_RESTORE)
Case $press
    Exit
EndSwitch
WEnd
Func _MY_NCHITTEST($hWnd, $uMsg, $wParam, $lParam)
    Local $hGUI = WinGetHandle("Informazioni su -aggiorna il mio mys-")
    Switch $hWnd
        Case $hGUI
            Local $aPos = WinGetPos($hWnd)
            If Abs(BitAND(BitShift($lParam, 16), 0xFFFF) - $aPos[1]) < 220 And Abs(BitAND(BitShift($lParam, 16), 0xFFFF) - $aPos[1]) > 40 Then Return $HTCAPTION
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_MY_NCHITTEST
Edited by BrewManNH

If I posted any code, assume that code was written using the latest release version unless stated otherwise. Also, if it doesn't work on XP I can't help with that because I don't have access to XP, and I'm not going to.
Give a programmer the correct code and he can do his work for a day. Teach a programmer to debug and he can do his work for a lifetime - by Chirag Gude
How to ask questions the smart way!

I hereby grant any person the right to use any code I post, that I am the original author of, on the autoitscript.com forums, unless I've specifically stated otherwise in the code or the thread post. If you do use my code all I ask, as a courtesy, is to make note of where you got it from.

Back up and restore Windows user files _Array.au3 - Modified array functions that include support for 2D arrays.  -  ColorChooser - An add-on for SciTE that pops up a color dialog so you can select and paste a color code into a script.  -  Customizable Splashscreen GUI w/Progress Bar - Create a custom "splash screen" GUI with a progress bar and custom label.  -  _FileGetProperty - Retrieve the properties of a file  -  SciTE Toolbar - A toolbar demo for use with the SciTE editor  -  GUIRegisterMsg demo - Demo script to show how to use the Windows messages to interact with controls and your GUI.  -   Latin Square password generator

Share this post


Link to post
Share on other sites

thank you so much!

Melba23:

thank you for your example, i find it very helpful!

UEZ:

i used:

#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <SendMessage.au3>

Global Const $SC_DRAGMOVE = 0xF012
$gui = GUICreate("Informazioni su -aggiorna il mio mys-", 522, 218, 192, 124, $WS_POPUP)
$id=GUICtrlCreateLabel("agg my mys",50,25,200,100)
GUICtrlSetfont($id,20)
GUICtrlSetcolor($id,0x4169E1)
GUICtrlCreateLabel("versione:       2,3,0",55,75,200,100)
GUICtrlCreateLabel("creato da:  MONITOR YOUR STOCKS                     @company                                                (SERVERMANIA)",55,100,200,100)
$press=GUICtrlCreateButton("Visualizzazione completata!",350,160,150,35)
_WinAPI_SetLayeredWindowAttributes($gui, 0x01, 255)
GUISetState(@SW_SHOW)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_MINIMIZE
    GUISetState(@SW_RESTORE)
Case $press
    Exit
Case $GUI_EVENT_PRIMARYDOWN
_SendMessage($gui, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
EndSwitch
WEnd

BrewManNH:

your code is so good! ;-)


ehi ehi ehi, what is your name?

Share this post


Link to post
Share on other sites

#11 ·  Posted (edited)

Sorry, but for me it was not clear what you want to do exactly with the GUI!

Anyway, you got several solutions now!

Br,

UEZ

Edited by UEZ

Please don't send me any personal message and ask for support! I will not reply!

Selection of finest graphical examples at Codepen.io

The own fart smells best!
Her 'sikim hıyar' diyene bir avuç tuz alıp koşma!
¯\_(ツ)_/¯  ٩(●̮̮̃•̃)۶ ٩(-̮̮̃-̃)۶ૐ

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0