Function in StringRegexReplace?

[golfinhu]

hi people, fine?

a have one question....

how do I put a function inside the stringregexpreplace?

example:

$read = StringRegExpReplace($read, 'v_assunto\s?=\s?([\w+\.+]+)z', stringlower($1))

undestend?

thanks!

[Melba23]

golfinhu,

how do I put a function inside the stringregexpreplace?

You do not - you let the SRER do its work and then run StringLower on the result like this:

$read = StringLower(StringRegExpReplace($read, 'v_assunto\s?=\s?([\w+\.+]+)z', '$1'))

M23

[golfinhu]

golfinhu,

You do not - you let the SRER do its work and then run StringLower on the result like this:

$read = StringLower(StringRegExpReplace($read, 'v_assunto\s?=\s?([\w+\.+]+)z', '$1'))

M23

worked perfectly

thankyou so much!

edit:

he left the all strings lowercase!

example:

$string = '<a href="máquina-de-macarrão" title="Máquina de Macarrão"><img src="arquivos/destaque01.jpg" alt="Máquina de Macarrão" /></a>'
$string = StringUpper(StringRegExpReplace($string, '<a href="(.+?)"', '<a href="$1"'))
MsgBox(0,'',$string)

=/

I'll try another way

but thanks a lot!

Edited January 6, 2011 by golfinhu

[jchd]

Do you mean something like this:

$string = '<a href="máquina-de-macarrão" title="Máquina de Macarrão"><img src="arquivos/destaque01.jpg" alt="Máquina de Macarrão" /></a>'
$string = execute(StringRegExpReplace($string, '(<a href=")(.+?)(".*)', "'$1' & StringUpper('$2') & '$3'"))
_consolewrite($string & @LF)

Func _ConsoleWrite($sString)
    Local $aResult = DllCall("kernel32.dll", "int", "WideCharToMultiByte", "uint", 65001, "dword", 0, "wstr", $sString, "int", -1, _
                                "ptr", 0, "int", 0, "ptr", 0, "ptr", 0)
    If @error Then Return SetError(1, @error, 0)
    Local $tText = DllStructCreate("char[" & $aResult[0] & "]")
    $aResult = DllCall("Kernel32.dll", "int", "WideCharToMultiByte", "uint", 65001, "dword", 0, "wstr", $sString, "int", -1, _
                            "ptr", DllStructGetPtr($tText), "int", $aResult[0], "ptr", 0, "ptr", 0)
    If @error Then Return SetError(2, @error, 0)
    ConsoleWrite(DllStructGetData($tText, 1))
EndFunc

Beware embedded quotes in the text as they will break things down. Use StringReplace($sString, "'", "''", 0, 1) to escape them:

[Mat]

I wrote a function to do exactly that a while ago based on what php has Other people then replied with some alternatives to get a similar effect with regex and execute.

Usage in this case:

$read = "v_assunto = TesTiNg.tHisiS.a.tESt.z"
$read = StringRegExpReplaceCallback($read, 'v_assunto\s?=\s?([\w+\.+]+)z', "MyStringLower")

ConsoleWrite($read & @LF)

Func MyStringLower($asMatches)
    Return StringLower($asMatches[1])
EndFunc  ;==>MyStringLower

Func StringRegExpReplaceCallback($sString, $sPattern, $sFunc, $iLimit = 0)
    Local $iOffset = 1, $iDone = 0, $iMatchOffset

    While True
        $aRes = StringRegExp($sString, $sPattern, 2, $iOffset)
        If @error Then ExitLoop

        $sRet = Call($sFunc, $aRes)
        If @error Then Return SetError(@error, $iDone, $sString)

        $iOffset = StringInStr($sString, $aRes[0], 1, 1, $iOffset)
        $sString = StringLeft($sString, $iOffset - 1) & $sRet & StringMid($sString, $iOffset + StringLen($aRes[0]))
        $iOffset += StringLen($sRet)

        $iDone += 1
        If $iDone = $iLimit Then ExitLoop
    WEnd

    Return SetExtended($iDone, $sString)
EndFunc   ;==>StringRegExpReplaceCallback

Edit: Added example value for $read

Edited January 6, 2011 by Mat

[golfinhu]

both worked perfectly!

thankyou very much! =)